Блог

У меня есть рабочая тетрадь со множеством листов. У меня есть рабочий лист с индексом, в котором перечислены имена рабочих листов в столбце B и вопрос «Да/нет» в столбце c. Мне нужен код, который, когда я нажму «ДА», откроет рабочий лист, которому он соответствует. Когда я нажму «НЕТ», он скроет рабочий лист. Имена в списке точно соответствуют названиям рабочих листов. Я предполагаю, что это будет с петлей?

Диапазон от B27 до C61

Если мы предположим, что столбец 2 содержит название листа, а столбец 3 содержит либо Да, либо Нет, то этот код сделает это с помощью двойного щелчка:

 Option Explicit

Private Function GetSheet(SheetName As String) As Worksheet
    On Error Resume Next
    Set GetSheet = ThisWorkbook.Sheets(SheetName)
    If Err.Number <> 0 Then
        Err.Clear
    End If
End Function

Private Sub ShowHideClick(Rng As Range, ActivateSheet As Boolean)
    Dim RowNum As Long, ColNum As Long
    Dim YesNo As String
    Dim SheetName As String
    Dim Sht As Worksheet
    
    RowNum = Rng.Row
    ColNum = Rng.Column
    If Not (RowNum >= 27 And RowNum <= 61 And ColNum = 3) Then Exit Sub
    YesNo = Rng
    If YesNo <> "Yes" And YesNo <> "No" Then Exit Sub
    SheetName = Rng.Offset(0, -1)
    Set Sht = GetSheet(SheetName)
    If Sht Is Nothing Then Exit Sub
    If YesNo = "Yes" Then
        If Sht.Visible = xlSheetVeryHidden Then
            Sht.Visible = xlSheetHidden
        End If
        Sht.Visible = xlSheetVisible
        If ActivateSheet Then
            Sht.Activate
        End If
        Rng.Value = "No"
    Else
        If Sht.Visible = xlSheetVisible Then
            Sht.Visible = xlSheetHidden
        End If
        Rng.Value = "Yes"
    End If
End Sub

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Cancel = True
    ShowHideClick Target, True
End Sub

 

Вставьте код в таблицу woorksheet, содержащую таблицу «Да/нет».