Блог

Главная - Вопросы по программированию - XSL Создает таблицу и заполняет значения столбцов из повторяющихся значений узлов

XSL Создает таблицу и заполняет значения столбцов из повторяющихся значений узлов

#xslt

Вопрос:

Можно ли взять приведенный ниже XML и построить таблицу, которая создает строку для каждого Attribute узла, а затем помещает значение Letter в правильный столбец?

Я попытался привести здесь пример, но не смог заставить его работать.

Спасибо.

Примечание: x показано в таблице, но может быть фактическим значением

 <?xml version="1.0" encoding="utf-8"?>
<Root>
  <AttributeList>
    <Attribute>
      <Name>One</Name>
      <Letter Value="A"/>
    </Attribute>
    <Attribute>
      <Name>Two</Name>
      <Letter Value="B"/>
      <Letter Value="C"/>
    </Attribute>
    <Attribute>
      <Name>Three</Name>
      <Letter Value="A"/>
      <Letter Value="B"/>
      <Letter Value="C"/>
    </Attribute>
    <Attribute>
      <Name>Four</Name>
      <Letter Value="C"/>
    </Attribute>
  </AttributeList>
</Root>
Атрибут A B C
Один x
Два x x
Три x x x
Четыре x

Мой XSLT в настоящее время выглядит так…

 <?xml version="1.0" encoding="UTF-8"?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
  <xsl:output method="html" doctype-public="XSLT-compat" omit-xml-declaration="yes" encoding="UTF-8" indent="yes"/>
  
  <xsl:variable name="end" select="number(3)"/>
  <xsl:variable name="increment" select="number(1)"/>
  
  <xsl:template match="//Root">
    <html>
      <head/>
      <body>
        <table>
          <tbody>
            <tr>
              <th>Attibute</th>
              <th>A</th>
              <th>B</th>
              <th>C</th>
            </tr>
            
      <xsl:for-each select="//Attribute">
        <tr>
      <td>
          <xsl:value-of select="Name"/>
      </td>
          <xsl:variable name="start" select="number(1)"/>
          <xsl:call-template name="loop">
            <xsl:with-param name="counter" select="$start"/>
          </xsl:call-template>
        </tr>
      </xsl:for-each>
          </tbody>
        </table>
      </body>
    </html>
  </xsl:template>
  
  
  
  <xsl:template name="loop">
    <xsl:param name="counter"/>
    <xsl:if test="$counter amp;<= $end">
      <td>
      <xsl:value-of select="Letter/@Value"/>
      </td>
      <xsl:call-template name="loop">
        <xsl:with-param name="counter" select="$counter   $increment"/>
      </xsl:call-template>
    </xsl:if>
  </xsl:template>

</xsl:transform>

Ответ №1:

Не могли бы вы сделать просто:

 <xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" encoding="utf-8" />
  
<xsl:template match="/Root">
    <html>
        <head/>
        <body>
            <table>
                <thead>
                    <tr>
                        <th>Attribute</th>
                        <th>A</th>
                        <th>B</th>
                        <th>C</th>
                    </tr>
                </thead>
                <tbody>
                    <xsl:for-each select="AttributeList/Attribute">
                        <tr>
                            <td>
                                <xsl:value-of select="Name"/>
                            </td>
                            <td>
                                <xsl:if test="Letter/@Value='A'">x</xsl:if>
                            </td>
                            <td>
                                <xsl:if test="Letter/@Value='B'">x</xsl:if>
                            </td>
                            <td>
                                <xsl:if test="Letter/@Value='C'">x</xsl:if>
                            </td>
                        </tr>
                    </xsl:for-each>
                </tbody>
            </table>
        </body>
    </html>
</xsl:template>

</xsl:stylesheet>

P.S. Если вы хотите, вы могли бы сделать это полностью универсальным, без жесткого кодирования значений:

XSLT 2.0

 <xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" encoding="utf-8" />
  
<xsl:template match="/Root">
    <xsl:variable name="cols" select="distinct-values(AttributeList/Attribute/Letter/@Value)" />
    <html>
        <head/>
        <body>
            <table>
                <thead>
                    <tr>
                        <th>Attribute</th>
                        <xsl:for-each select="$cols">
                            <th>
                                <xsl:value-of select="."/>
                            </th>
                        </xsl:for-each>
                    </tr>
                </thead>
                <tbody>
                    <xsl:for-each select="AttributeList/Attribute">                         
                        <xsl:variable name="letters" select="Letter/@Value" />
                        <tr>
                            <td>
                                <xsl:value-of select="Name"/>
                            </td>
                            <xsl:for-each select="$cols">
                                <td>
                                    <xsl:if test=". = $letters">x</xsl:if>
                                </td>
                            </xsl:for-each>
                        </tr>
                    </xsl:for-each>
                </tbody>
            </table>
        </body>
    </html>
</xsl:template>

</xsl:stylesheet>

Комментарии:

1. Это гораздо лучшее решение. ty.

2. Привет, Майкл, Для ответа XSLT 2.0 Можно ли выполнить сортировку по переменной $cols?

3. Я решил эту проблему, поместив <xsl:сортировка> под каждым <xsl:сортировка><xsl:для каждого>. Я использовал <xsl:sort select=»верхний регистр (.)»/>, чтобы убедиться, что сортировка работает правильно с символами верхнего/нижнего регистра.

Метки: