Блог

Главная - Вопросы по программированию - XSLT: сумма с условием

XSLT: сумма с условием

#xml #xslt

Вопрос:

Я хотел бы преобразовать приведенный ниже XML через XSLT, нащупав на основе тега имени, и получить общую сумму тега с условием (Статус = «Черновик») . Пожалуйста, посоветуйте

Входной XML:

 <?xml version='1.0' encoding='UTF-8'?>
<wd:Data xmlns:wd="urn:com.test/bsvc">
    <wd:Entry>
        <wd:Name>ABC</wd:Name>
        <wd:ID>123</wd:ID>
        <wd:Amount>10</wd:Amount>
        <wd:Status>Pending</wd:Status>
    </wd:Entry>
    <wd:Entry>
        <wd:Name>ABC</wd:Name>
        <wd:ID>123</wd:ID>
        <wd:Amount>20</wd:Amount>
        <wd:Status>Draft</wd:Status>
    </wd:Entry>
    <wd:Entry>
        <wd:Name>ABC</wd:Name>
        <wd:ID>123</wd:ID>
        <wd:Amount>30</wd:Amount>
        <wd:Status>Draft</wd:Status>
    </wd:Entry>
</wd:Data>

XSLT

 <xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:wd="urn:com.test/bsvc" exclude-result-prefixes="wd">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
    
    <xsl:template match="/">
        
        
        <xsl:for-each-group select="wd:Data/wd:Entry" group-by="wd:Name">
            
            
            <Details>
                <ID>
                    <xsl:value-of select="wd:ID"/>
                </ID>
                <Name>
                    <xsl:value-of select="wd:Name"/>
                </Name>
                <Total_Unverified_Amount>
                    <xsl:value-of select='format-number(sum(current-group()/wd:Amount),"##.00")'/>
                </Total_Unverified_Amount>
                <Charges_Draft>
                    <xsl:value-of select="sum(current-group()/wd:Amount[current-group()/wd:Status = 'Draft'])"/>
                </Charges_Draft>
            </Details>
        </xsl:for-each-group>
        
    </xsl:template>
</xsl:stylesheet>

Сгенерированный результат:

 <Details>
   <ID>123</ID>
   <Name>ABC</Name>
   <Total_Unverified_Amount>60.00</Total_Unverified_Amount>
   <Charges_Draft>60</Charges_Draft>
</Details>

Желаемый Результат:

 <Details>
   <ID>123</ID>
   <Name>ABC</Name>
   <Total_Unverified_Amount>60.00</Total_Unverified_Amount>
   <Charges_Draft>50</Charges_Draft>
</Details>

Я хотел бы преобразовать приведенный ниже XML через XSLT, нащупав на основе тега имени, и получить общую сумму тега с условием (Статус = «Черновик») . Пожалуйста, посоветуйте

Ответ №1:

Вместо:

 <Charges_Draft>
    <xsl:value-of select="sum(current-group()/wd:Amount[current-group()/wd:Status = 'Draft'])"/>
</Charges_Draft>

использовать:

 <Charges_Draft>
    <xsl:value-of select="sum(current-group()[wd:Status = 'Draft']/wd:Amount)"/>
</Charges_Draft>

Чтобы уточнить: ваш предикат:

 [current-group()/wd:Status = 'Draft']

возвращает значение true всякий wd:Entry раз, когда в текущей группе есть хотя бы один, чей wd:Status "Draft" . Этот результат затем применяется ко всем членам текущей тестируемой группы одинаково.

Метки: