Блог

У меня есть репозиторий Git с кодом Terraform, который развертывается в AWS. Я добавляю Localstack в этот репозиторий, чтобы я мог выполнить тестирование проверки более высокого уровня перед планом и подать заявку в свой реальный аккаунт AWS. Чтобы использовать Localstack, я должен создать нового поставщика с пользовательской конечной точкой:

 provider "aws" {
  alias  = "real"
  region = "${local.aws_region}"
}

provider "aws" {
  alias                       = "fake"
  region                      = "${local.aws_region}"
  access_key                  = "fake"
  secret_key                  = "fake"
  skip_credentials_validation = true
  skip_metadata_api_check     = true
  skip_requesting_account_id  = true

  endpoints {
    dynamodb = "http://localhost:4566"
    lambda   = "http://localhost:4566"
    kinesis  = "http://localhost:4566"
  }
}
 

Как я могу использовать одного поставщика для Localstack и одного поставщика с AWS без дублирования моего кода?

К сожалению, поскольку структура конфигурации в этих двух случаях значительно отличается, на самом деле невозможно сделать это динамически переключаемым без того, чтобы результирующая конфигурация не выглядела довольно сложной, но можно использовать операторы и блоки выражений языка Terraform dynamic для условной установки всех аргументов поставщика и, таким образом, иметь единую конфигурацию поставщика сдинамические настройки, а не две отдельные конфигурации поставщика.

Первое, что нужно решить, это то, как вы будете выбирать между двумя возможностями. Поскольку ваша псевдоинфраструктура localstack неизбежно будет отличаться от «реальной» инфраструктуры, я ожидаю, что вы захотите использовать для нее отдельное состояние, и поэтому это может быть разумной ситуацией для использования отдельного рабочего пространства для разработки / тестирования, и я напишу этот пример, предполагая, что конфигурация localstack должна бытьактивен всякий dev раз, когда выбрано рабочее пространство. Если это не то, что вы хотите, то, надеюсь, этого все равно должно быть достаточно, чтобы адаптироваться в соответствии с вашими потребностями.

 locals {
  use_localstack = (terraform.workspace == "dev")

  aws_settings = (
    local.use_localstack ?
    {
      region     = local.aws_region
      access_key = "fake"
      secret_key = "fake"

      skip_credentials_validation = true
      skip_metadata_api_check     = true
      skip_requesting_account_id  = true

      override_endpoint = "http://localhost:4566"
    } :
    {
      region     = local.aws_region
      access_key = null
      secret_key = null
      
      skip_credentials_validation = null
      skip_metadata_api_check     = null
      skip_requesting_account_id  = null

      override_endpoint = null
    }
  )
}

provider "aws" {
  region     = local.aws_settings.region
  access_key = local.aws_settings.access_key
  secret_key = local.aws_settings.secret_key

  skip_credentials_validation = local.aws_settings.skip_credentials_validation
  skip_metadata_api_check     = local.aws_settings.skip_metadata_api_check
  skip_requesting_account_id  = local.aws_settings.skip_requesting_account_id

  dynamic "endpoints" {
    for_each = local.aws_settings.override_endpoint[*]
    content {
      dynamodb = endpoints.value
      lambda   = endpoints.value
      kinesis  = endpoints.value
    }
  }
}