Блог

Я новичок в Джулии и только что узнал, что Джулия может генерировать общие методы, изменяя сигнатуру функции.

 function round_number(x::Float64)
  return round(x)
end

round_number(3.1415)
round_number(3)

function round_number(x::Int64)
  return x
end

round_number(3)
 

Когда я обнаружил, что функция test_interpolated не может работать с числом и строкой, я попытался посмотреть, смогу ли я сгенерировать новую подпись для расширения isless . К сожалению, это не сработало.

 function test_interpolated(a, b)
  if a < b
      "$a is less than $b"
  elseif a > b
      "$a is greater than $b"
  else
      "$a is equal to $b"
  end
end

test_interpolated(3.14, 3.14)
test_interpolated(3.14, "3.14")

function isless(x::AbstractFloat, y::AbstractString)
  return x < float64(y)
end

test_interpolated(3.14, "3.14")
 

Неужели я неправильно понял эту концепцию?

Сначала обратите внимание, что float64 в Julia нет функции. Чтобы разобрать строку как число, вам нужно использовать parse функцию:

 parse(Float64, "3.14")
 

Вторая вещь в вашем коде заключается в том, что:

 function isless(x::AbstractFloat, y::AbstractString)
  return x < float64(y)
end
 

создает новую функцию с именем isless в вашем текущем модуле (скорее Main всего, если вы работаете, например, в REPL).

Чтобы добавить метод к isless функции, определенной в Base модуле, вам нужно будет написать:

 function Base.isless(x::AbstractFloat, y::AbstractString)
  return x < float64(y)
end
 

(обратите внимание на Base. префикс)

Хотя Джулия допускает это, вы никогда не должны делать это в своем коде. Этот стиль называется пиратством типов и объясняется здесь .

Короче говоря, вы добавляете метод к функции из Base модуля AbstractFloat , и оба AbstractString они также определены в Base модуле. Проблема в том, что добавление такого метода может привести к поломке другого кода, который в этом случае предполагает, что isless при передаче AbstractFloat и AbstractString выдает ошибку.

Способ, которым вы должны определить свою функцию, например, следующим образом:

 toreal(x::Real) = x

toreal(x::AbstractString) = parse(Float64, x)

function test_interpolated(a::Real, b::Real)
  if a < b
      "$a is less than $b"
  elseif a > b
      "$a is greater than $b"
  else
      "$a is equal to $b"
  end
end

test_interpolated(a, b) = test_interpolated(toreal(a), toreal(b))
 

Таким образом, вы гарантируете, что у вас есть один конкретный метод с узкой сигнатурой, реализующий логику для действительных чисел, а другой метод для test_interpolated этого имеет широкую сигнатуру, которая выполняет преобразование в соответствующие типы.

Обратите внимание, что я использую Real not AbstractFloat , поскольку сравнение с < гарантированно определяется для двух Real значений, и вы, скорее всего, хотите, чтобы ваша функция, например, принимала целые числа.

Подход, который я показываю, объясняется здесь .

Редактировать

Пример неоднозначности отправки. Используйте свежий сеанс Julia 1.7.0:

 julia> struct T end

julia> Base.propertynames(::T, ::Integer) = nothing

julia> propertynames(T(), true)
ERROR: MethodError: propertynames(::T, ::Bool) is ambiguous. Candidates:
  propertynames(x, private::Bool) in Base at reflection.jl:1666
  propertynames(::T, ::Integer) in Main at REPL[2]:1