Блог

в настоящее время я создаю 2D-игру в Firemonkey для своего телефона Android, используя некоторые элементы управления временем и контролируя их положения и углы. Все просто. Я попытался использовать свой обычный способ зацикливания, который хорошо / безупречно работает в Windows, но терпит неудачу на Android.

Метод №1: цикл «Без конца» (плохой)

Моя главная проблема в том, что я хочу избежать нежелательного / неожиданного поведения, используя «бесконечный цикл», подобный этому, где я должен вызвать Application.ProcessMessages() :

 while (Game.IsRunning()) do
begin
  { Update game objects and stuff }
  World.Update();


  { Process window messages, or the window will not respond anymore obviously }
  Application.ProcessMessages(); { And thats what i want to avoid }
end;
 

Проблема в том, что, поскольку я застрял в цикле, а также вызываю процедуру для обработки сообщений, я могу столкнуться со многими проблемами, а также я просто не думаю, что это хороший способ.

Способ №2: TTimer (даже не думайте об этом 😉 )

Поскольку TTimer ужасен во многих отношениях и не предназначен для использования для таких целей, подход, при котором я просто ставлю TTimer с минимальным интервалом, отпадает. Кроме того, я никогда не пробовал другие таймеры, кроме этого, но если есть действительно подходящий для игр, я, конечно, попробую его 🙂

Метод № 3: OnIdle — Как я обычно делаю это в Windows

В Windows я могу использовать это приложение.OnIdle-Событие.

 procedure GameLoop(Sender: TObject; var Done: Boolean);
begin
  { Update game objects and stuff }
  World.Update();

  { Set done to false }
  Done := False;
end;

...

Application.OnIdle := GameLoop;
 

Он вызывается каждый раз, когда приложение работает на холостом ходу над сообщениями Windows. Производительность кажется такой же или немного хуже по сравнению с # 1, а общая архитектура намного надежнее, поэтому я обычно использую этот метод. Однако на Android кажется, что он вызывается по-другому в сочетании с TForm.MouseMove. Там, где в Windows OnIdle продолжает работать отлично, на Android он будет отставать / останавливаться, пока TForm.MouseMove вызывается из сенсорного ввода (RAD Studio автоматически компилирует его в события касания)

Однако я могу запустить OnIdle самостоятельно в событии MouseMove, вызвав Application.DoIdle и «assist» «Цикл», где, я думаю, он пропускает вызов beimg, но это работает также очень плохо и снова приводит к нежелательному поведению и ухудшению производительности при работе с сенсорным вводом.

И это возвращает меня к методу № 1, и, похоже, на данный момент он работает лучше всего на Android. Есть ли какой-либо другой способ создания надежного способа (постоянно и быстро вызываемого события, такого как OnIdle или около того) создания такого цикла или какой-либо способ избежать проблем, с которыми я сталкиваюсь в методе # 3 в сочетании с MouseMove-Events? Похоже, что телефон Android недостаточно мощный, чтобы иметь достаточно «времени простоя» рядом с формой-события и обновления мира

Кроме того, могу ли я рассмотреть возможность использования потока для мировой логики и рядом с ним метода # 1 в моей основной форме / потоке для обновления рендеринга? Безопасно ли обновлять элементы управления формой с помощью бесконечного цикла (с помощью Application.ProcessMessages ()) и получение отображаемых данных из другого потока, работающего с миром, объектами и так далее?

Я думаю, что допустимым вариантом является реализация TAnimation и переопределение ProcessAnimation. танимация автоматически запланирована при запуске через TAnimator.

   TGameLoop = class(TAnimation)
  protected
    procedure ProcessAnimation; override;
  end;
  [...]
  procedure TGameLoop.ProcessAnimation;
  begin
    //call updates
  end;
 

и начал все вот так:

 procedure TForm1.FormCreate(Sender: TObject);
begin
  FLoop := TGameLoop.Create(Self);
  FLoop.Loop := True;
  FLoop.Name := 'GameLoop';
  FLoop.Parent := Self;
  TAnimator.StartAnimation(Self, 'GameLoop');
end;
 

По умолчанию для анимации установлено значение 60 кадров в секунду. Одна вещь, которую я не мог понять прямо сейчас, — это как вычислить время задержки с момента последнего вызова, используя только свойства TAnimation . Это важно для работы с переменным временем цикла. Но вы можете сделать это сами, используя System.Диагностика.TStopwatch. Остановите часы в начале ProcessAnimation и получите тики, запустите новый после завершения ProcessAnimation.

РЕДАКТИРОВАТЬ: базовый пример для Deltatime (прошедшее время с момента последнего вызова в секундах). Учитывая, что вы разместили Viewport3D в Form1, добавили TCube с именем Cube1, TGameLoop объявляется в том же блоке, что и Form1 (я знаю, уродливый, но демонстрационный), а TGameLoop имеет поле FWatch типа TStopWatch.

 procedure TGameLoop.ProcessAnimation;
var
  LDelta: Single;
begin
  FWatch.Stop;
  LDelta := FWatch.ElapsedTicks / FWatch.Frequency;
  Form1.Cube1.RotationAngle.Y := Form1.Cube1.RotationAngle.Y   50*LDelta;
  FWatch := TStopwatch.StartNew();
end;
 

РЕДАКТИРОВАНИЕ 2: лучший пример, который распределяет ошибки округления / измерения по всей игре — время жизни немного лучше. Вместо того, чтобы измерять только между вызовами, мы измеряем с первого кадра. В TGameLoop появилось новое поле FLastElapsedTicks (двойное)

 procedure TGameLoop.FirstFrame;
begin
  FWatch := TStopWatch.StartNew();
end;

procedure TGameLoop.ProcessAnimation;
var
  LDelta: Single;
  LTickDelta, LElapsed: Double;
begin
  LElapsed := FWatch.ElapsedTicks;
  LTickDelta := LElapsed - FLastElapsedTicks;
  FLastElapsedTicks := LElapsed;
  LDelta := LTickDelta / FWatch.Frequency;
  Form1.Cube1.RotationAngle.Y := Form1.Cube1.RotationAngle.Y   50*LDelta;
end;