Блог

Я не понимаю, как правильно использовать заголовки в сочетании с разрывами страниц. У меня есть отчет в формате Word, который я создаю с помощью VBA из Excel. Базовая структура должна быть такой:

страница 1

• заголовок
• текст
• текст
• разрыв страницы

страница 2

• текст
• текст
• текст
• текст

Результат, который я получаю, выглядит так:

страница 1

• заголовок
• текст
• текст

страница 2

• разрыв страницы
• пустая страница
• пустая страница
• пустая страница

страница 3

• текст
• текст
• текст
• текст

Разрыв страницы создается с использованием этой части кода:

 'Launches word application
Set Wapp = CreateObject("Word.Application") 
With Wapp
    With .Selection
        'New paragraph amp; line
        .TypeParagraph
        .TypeText St1
        .TypeText St2
        'Collapses selection
        .Collapse Direction:=0 'Direction:=wdCollapseEnd
        'New page
        .InsertBreak Type:=7 'Type:=wdPageBreak
    End With
End With
 

Я попытался изменить тип на 4 или 2, затем он не создает дополнительной страницы, но затем заголовок появляется на второй странице, а я этого не хочу. Также я пытался добавить эту строку при создании заголовка, но, похоже, это не работает:

 With Doc.PageSetup
    .DifferentFirstPageHeaderFooter = True
End With
 

Тогда я подумал, может быть, можно удалить пустую страницу, обнаружив абзац с разрывом страницы, и написал этот код:

 'Procedure will check if there are blank pages and remove them
Sub DeleteLastPageBreak(Wapp As Object)
Dim i As Long
Dim Doc As Word.Document
Dim P As Paragraph
    'Creates reference to Word document
    Set Doc = Wapp.ActiveDocument
    For Each P In Doc.Content.Paragraphs
        If P.Range.Characters.Count = 1 Then
            If P.Range.Characters(1) = vbFormFeed Then
                MsgBox "paragraph found"
            End If
        End If
    Next
End Sub

 

Кажется, что он не может обнаружить разрыв страницы. Что именно я делаю не так и как достичь желаемого результата?

Следующий код, в котором используется ссылка на Word (ранний связанный объект Word), может быть полезен для иллюстрации принципов.

 Option Explicit

Sub main()

    Dim myWord As Word.Application
    Set myWord = New Word.Application
    
    myWord.Visible = True
    myWord.Activate
    
    Dim myDoc As Word.Document
    Set myDoc = myWord.Documents.Add
    
    'Information for first section
    With myDoc.StoryRanges(wdMainTextStory)

        ' At this point there is only 1 section in the document
        With .Sections.Last
        
            With .Headers(wdHeaderFooterPrimary).Range
            
                .Paragraphs.Item(1).Range.Text = "This is paragraph1 in the header"
                
            End With
        
            With .Range.Paragraphs.Item(1).Range
            
                .Style = myDoc.Styles(WdBuiltinStyle.wdStyleHeading1)
                .Text = "MyHeadingText "
                .InsertParagraphAfter
                .Collapse Direction:=wdCollapseEnd
                .Text = "Paragraph 2"
                .InsertParagraphAfter
                .Collapse Direction:=wdCollapseEnd
                .Text = "paragraph 3"
                .Collapse Direction:=wdCollapseEnd
                'start a new section with next page enabled
                .InsertBreak Type:=WdBreakType.wdSectionBreakNextPage
                .Collapse Direction:=wdCollapseEnd
                With .Sections.Item(1).Headers(wdHeaderFooterPrimary)
                
                    .LinkToPrevious = False
                    .Range.Paragraphs.Last.Range.Text = "This is header in section 2 which is on a new page"
                    
                End With
                
                .Style = myDoc.Styles(WdBuiltinStyle.wdStyleHeading1)
                .Text = "MyHeadingText in section 2 (on a new page)"
                .InsertParagraphAfter
                .Collapse Direction:=wdCollapseEnd
                .Text = "Paragraph 2"
                .InsertParagraphAfter
                .Collapse Direction:=wdCollapseEnd
                .Text = "paragraph 3"
                .Collapse Direction:=wdCollapseEnd
            
            End With
            
        End With
        
    End With
                
End Sub