Блог

Кажется, существует несколько способов сделать полиморфизм в Perl, но все они кажутся мне «халтурными». Я несколько новичок в Perl, поэтому могу просто неправильно интерпретировать его, но я нахожу, что большинство примеров делают ваш код слишком неразборчивым и противоречивым.

Допустим, у вас есть класс виджетов, который содержит некоторые данные и методы, необходимые всем виджетам. Существует также несколько типов виджетов (например, календарь, расписание и т. Д.). И они должны взаимодействовать друг с другом (через родительский класс контейнера).

Стоит ли играть с пространством имен и превращать виджет в прототип?
Должен ли я давать каждому виджету ссылку на объект (один из типов) при создании экземпляра?
Просто забудьте о том, что типы являются объектами, и сделайте widget большим классом, в котором для каждого экземпляра используется только несколько методов в зависимости от того, какой тип установлен. Что-то еще?

Я родом из C / C , и мне трудно определиться с моделью программирования на Perl.

Кроме того, у меня нет строгих требований к безопасности типов или закрытым членам. Проект представляет собой веб-приложение среднего размера с несколькими разработчиками, и переносимость на другие проекты не является приоритетом. Хотя было бы полезно простое расширение без необходимости расшифровывать хаки Perl.

Подход «Современный Perl», вероятно, заключается в определении Widget как роли. Роль можно рассматривать как подобную mixin, интерфейсу или абстрактному базовому классу. Сделайте это с помощью Moose::Role или одной из его более легких альтернатив (Moo::Role, Role::Tiny).

 {
   package Widget;
   use Moo::Role;

   sub some_common_method {
      my $self = shift;
      ...;
   }

   sub another_common_method {
      my $self = shift;
      ...;
   }

   # Here we're indicating that all Widgets must
   # have a method called yet_another_common_method,
   # but we're not defining how that method should
   # be implemented.
   requires "yet_another_common_method";
}
 

Теперь вы можете создать класс, который выполняет эту роль:

 {
   package Calendar;
   use Moo;
   with "Widget";

   # Here's a member variable.
   has year => (is => "ro", required => 1);

   # Widget requires us to implement this.
   sub yet_another_common_method {
      my $self = shift;
      ...;
   }

   # We can override Widget's implementation
   # of this method.
   sub some_common_method {
      my $self = shift;
      ...;
   }

   # We can install hooks ("method modifiers")
   # to Widget's methods.
   before another_common_method => sub {
      my $self = shift;
      print STDERR "Calendar ", $self->year, ": another_common_method() was called.n";
   };
}
 

И еще:

 {
   package Schedule;
   use Moo;
   with "Widget", "Editable";

   sub yet_another_common_method {
      my $self = shift;
      ...;
   }
}
 

И используйте классы:

 my $calendar = Calendar->new( year => 2014 );
my $schedule = Schedule->new;

my @widgets = ($calendar, $schedule);

for (@widgets) {
   $_->some_common_method if $_->does('Widget');
}