Блог

На моем графике узел категории «Файл» «Владеет» многими узлами разных категорий. Я пытаюсь получить список файлов, включая количество подключенных узлов определенных категорий.

Мой текущий лучший запрос выглядит следующим образом:

 SELECT ?uuid ?fileName ?tableCount ?toCount
WHERE {
    ?uuid 'Category' 'File' .
    ?uuid 'Name' ?fileName .
    {
        SELECT (COUNT(*) as ?tableCount)
        WHERE
        {
            VALUES (?category ) { ('BaseTable') }
            ?uuid 'Owns' ?elemUUID .
            ?elemUUID 'Category' ?category .
        }   
    }
    {
        SELECT (COUNT(*) as ?toCount)
        WHERE
        {
            VALUES (?category ) { ('TableOccurrence') }
            ?uuid 'Owns' ?elemUUID .
            ?elemUUID 'Category' ?category .
        }   
    }
}
 

Вывод представляет собой отдельный список файлов, но подсчеты являются подсчетом для этой категории во ВСЕХ файлах (т. Е. Каждый файл имеет одинаковое значение для ?toCount , и каждый файл имеет одинаковое значение для ?tableCount ).

Очевидно, что я чего-то не понимаю в том, как работают подзапросы. Любая помощь будет с благодарностью принята.

Переменные во внутренних запросах не отображаются снаружи, если они не отображаются в выборе. Вместо этого вам следует выполнить такой запрос (простите за редактирование, но это значительно упростит отслеживание и для других пользователей):

 SELECT ?uuid ?fileName ?tableCount ?toCount
WHERE {
    ?uuid :category 'File' .
    ?uuid :name ?fileName .
    {
        SELECT ?uuid (COUNT(*) as ?tableCount)
        WHERE
        {
            VALUES (?category ) { ('BaseTable') }
            ?uuid :owns ?elemUUID .
            ?elemUUID :category ?category .
        }
        GROUP BY ?uuid   #This is the missing link
    }
    {
        SELECT ?uuid (COUNT(*) as ?toCount)
        WHERE
        {
            VALUES (?category ) { ('TableOccurrence') }
            ?uuid :owns ?elemUUID .
            ?elemUUID :category ?category .
        } 
        GROUP BY ?uuid  #and here again
    }
}