Блог

Главная - Вопросы по программированию - Как создать поле формулы для поля salesforce?

Как создать поле формулы для поля salesforce?

#if-statement #salesforce #crm

#if-statement #salesforce #crm

Вопрос:

Я пытаюсь создать поле формулы для поля salesforce. условие приведено ниже.

 if Company = "WIL" And (ShippingCountry = "United States" Or "USA") then
   "US"
elseif Company = "WST" And (ShippingCountry = "United States" Or "US") then
   "USA"
elseif ShippingCountry <> "" then
   ShippingCountry
elseif Company = "WIL" then
   "US"
elseif Company = "WST" then
   "USA"
else
   ""
end if

Комментарии:

1. Не могли бы вы предоставить более подробную информацию? С какими проблемами вы сталкиваетесь? Если редактор полей выдал сообщение об ошибке, пожалуйста, добавьте его в сообщение.

2. @ RubenDG Я работаю с Salesforce crm. Я создаю новое поле формулы для объекта account, и это условие для использования для создания поля формулы

Ответ №1:

Первые шаги — это всегда хорошее начало. Я бы предложил использовать поля формул и расширенные формулы.
Страницы документации об операторах и функциях формулы также могут быть полезны.

Имейте в виду, что вы должны использовать имена API полей, а не метки, поэтому Company__c .
If Company__c не является полем раскрывающегося списка:

 IF( AND(Company__c = 'WIL', OR(ShippingCountry = 'United States', ShippingCountry = 'USA')),
    'US',
    IF( AND(Company__c = 'WST', OR(ShippingCountry = 'United States', ShippingCountry = 'US')),
        'USA',
        IF( NOT( ISBLANK(ShippingCountry) ),
            ShippingCountry,
            IF( Company__c = 'WIL',
                'US',
                IF(Company__c = 'WST', 'USA', '') 
            ) 
        ) 
    ) 
)

If Company__c — это поле раскрывающегося списка, которое вы должны использовать ISPICKVAL(picklist_field, literal_value) , поэтому формула будет:

 IF( AND( ISPICKVAL(Company__c, 'WIL'), OR(ShippingCountry = 'United States', ShippingCountry = 'USA')),
    'US',
    IF( AND(ISPICKVAL(Company__c, 'WST'), OR(ShippingCountry = 'United States', ShippingCountry = 'US')),
        'USA',
        IF( NOT( ISBLANK(ShippingCountry) ),
            ShippingCountry,
            IF( ISPICKVAL(Company__c, 'WIL'),
                'US',
                IF( ISPICKVAL(Company__c, 'WST'), 'USA', '') 
            ) 
        ) 
    ) 
)