Блог

Я начинаю выполнять тесты с использованием платформы Spock в проекте Spring Boot Spring Data.

Проблема возникает, когда я пытаюсь издеваться над своим репозиторием, но, в частности, в каком-то методе, возврат которого является необязательным.

 Cannot invoke method orElse() on null object
java.lang.NullPointerException: Cannot invoke method orElse() on null object
    at br.com.moskit.jivochat.service.UserService.getResponsible(UserService.groovy:37)
    at br.com.moskit.jivochat.service.UserServiceTest.Retrive the responsible of interaction in JivoChat by configs of plugin item(UserServiceTest.groovy:65)
 

Моя реализация теста:

 class UserServiceTest extends Specification {

    UserService userService

    void setup() {
        userService = new UserService()
        userService.userRepository = Mock(UserRepository)
        GroovyMock(Optional)
    }


    def "Retrive the responsible of interaction in JivoChat by configs of plugin item"() {

        given: 'that exist a collection of JivoChat interaction configurations'

        List<Map> agents = null

        Map configs = [responsibleId: 1]

        userService.userRepository.findById(_) >> Optional.of(new User(username: "XPTO")).orElse("null")

        when: 'the main method is called'

        User user = userService.getResponsible(configs, agents)

        then: 'the method get last agent and search in DB by e-mail'
        1 * userService.userRepository.findById(_)
    }
}
 

Мой метод:

     User getResponsible(Map configs, List<Map> agents) {

        //Ommited...

        Integer responsibleId = configs.responsibleId as Integer
        Optional<User> userOptional = userRepository.findById(responsibleId)
        User user = userOptional.orElse(null)

        user
    }
 

Это классический вопрос, и ответ на него можно найти в главе руководства Spock «Комбинирование насмешек и заглушек»:

ПРИМЕЧАНИЕ: насмешка и отключение одного и того же вызова метода должны происходить в одном и том же взаимодействии.

Итак, решение выглядит следующим образом:

 package de.scrum_master.stackoverflow.q66208875

class User {
  int id
  String username
}
 

 package de.scrum_master.stackoverflow.q66208875

class UserRepository {
  Optional<User> findById(int id) {
    Optional.of(new User(id: id, username: "User #$id"))
  }
}
 

 package de.scrum_master.stackoverflow.q66208875

class UserService {
  UserRepository userRepository = new UserRepository()

  User getResponsible(Map configs, List<Map> agents) {
    Integer responsibleId = configs.responsibleId as Integer
    Optional<User> userOptional = userRepository.findById(responsibleId)
    User user = userOptional.orElse(null)
    user
  }
}
 

 package de.scrum_master.stackoverflow.q66208875

import spock.lang.Specification

class UserServiceTest extends Specification {
  UserService userService

  void setup() {
    userService = new UserService()
    userService.userRepository = Mock(UserRepository)
  }

  def "retrieve the responsible of interaction in JivoChat by configs of plugin item"() {
    given: 'that exist a collection of JivoChat interaction configurations'
    List<Map> agents = null
    Map configs = [responsibleId: 1]

    when: 'the main method is called'
    User user = userService.getResponsible(configs, agents)

    then: 'the method get last agent and search in DB by e-mail'
    1 * userService.userRepository.findById(_) >> Optional.of(new User(username: "XPTO"))//.orElse("null")
  }
}
 

Посмотрите, как я объединил заглушку результата метода и проверку макетного взаимодействия в одной строке?

Вам также не нужны никакие GroovyMock(Optional) , для чего бы это ни предназначалось. Вы также хотите убедиться findById(_) , что правильный тип результата и удаление false .orElse("null") .