Блог

Вот мой код SQL Server:

 CREATE PROCEDURE [dbo].[usp_GetLeaveDateBewteenStartAndEndDate]      
    (@UserEmail VARCHAR(100) = NULL,      
     @FromDate VARCHAR(10) = NULL,      
     @ToDate VARCHAR(10) = NULL)      
AS      
BEGIN      
    --SELECT       
    --GETDATE() AS [Date]      
    --,CONVERT(VARCHAR(10),GETDATE(),103) AS ShortDate      
    --,'Monday' as [DayName]      
    --,'Full Day' as [Session]      
    --, 1 as NoOfDays      
    --,'Work Day' as [Status]      
    --,'W' as StatusCode      
    
     DECLARE @Result AS TABLE    
                        (    
                            Date       DATETIME,
                            ShortDate  VARCHAR(50),
                            DayNames   VARCHAR(50),    
                            Session    VARCHAR(20),    
                            NoOfDays   INT,
                            Status     VARCHAR(50),    
                            StatusCode VARCHAR(2)    
                        )        
       
    DECLARE @dayscount INT 

    SET @dayscount =  CAST(DATEDIFF(DAY, CONVERT(DATE, @FromDate, 103), CONVERT(DATE, @ToDate, 103)) AS INT)   1

    DECLARE @daysval INT
    SET @daysval = 0

    WHILE (@daysval < @dayscount)
    BEGIN
        INSERT INTO @Result (Date, ShortDate, DayNames, Session, NoOfDays, Status, StatusCode)    
        VALUES (CONVERT(DATETIME, DATEADD(DAY, @daysval, CONVERT(DATE, @FromDate, 103)), 103), CONVERT(VARCHAR(50), DATEADD(DAY, @daysval, CONVERT(DATE, @FromDate, 103)), 103),     
                DATENAME(dw, CONVERT(VARCHAR(50), DATEADD(DAY, @daysval, '07/02/2021'), 103)), 
                'Full Session', 1, 'Work Day', 'W')    
    
        SET @daysval = @daysval   1

        DECLARE @daycheck NVARCHAR(100)

        SELECT @daycheck = DayNames 
        FROM @Result
   
        IF (@daycheck = 'sunday')
        BEGIN
            UPDATE @Result
            SET Status = '', StatusCode = ''
        END
    END
      
    SELECT * FROM @Result   
END
 

И после выполнения моего запроса я получаю этот результат:

 EXEC [dbo].[usp_GetLeaveDateBewteenStartAndEndDate] NULL, '03/02/2021', '05/02/2021'

Date    ShortDate   DayNames    Session NoOfDays    Status  StatusCode  
-----------------------------------------------------------------------
2021-02-03 00:00:00.000 03/02/2021  Sunday  Full Session    1       
2021-02-04 00:00:00.000 04/02/2021  Sunday  Full Session    1       
2021-02-05 00:00:00.000 05/02/2021  Wednesday   Full Session    1   Work Day    W
 

Для 01/02/2021 daynames должен быть понедельник, а 05/02/2021 должен быть вторник.

Я не могу точно сказать, почему вы видите эти результаты, поскольку у меня нет ваших входных параметров. Но в вашем коде есть ряд фундаментальных ошибок.

1. select @daycheck = DayNames from @Result не проверяет, какую строку он запрашивает.
2. update @Result set Status = '' , StatusCode = '' имеет ту же проблему.
3. Вы конвертируете даты varchar влево и вправо. Сохраняйте значения в том формате, в котором они должны быть, и просто конвертируйте там, где это необходимо для отображения.
4. Кроме того, вы должны проходить через даты от и до как date нет varchar .
5. Для всего этого нет необходимости в while цикле или табличной переменной. Это можно сделать с помощью таблицы подсчета. Я использовал хорошо известную таблицу Ицика Бен-Гана ниже.

 WITH
    L0 AS ( SELECT 1 AS c 
            FROM (VALUES(1),(1),(1),(1),(1),(1),(1),(1),
                        (1),(1),(1),(1),(1),(1),(1),(1)) AS D(c) ),
    L1 AS ( SELECT 1 AS c FROM L0 AS A CROSS JOIN L0 AS B ),
    L2 AS ( SELECT 1 AS c FROM L1 AS A CROSS JOIN L1 AS B ),
    L3 AS ( SELECT 1 AS c FROM L2 AS A CROSS JOIN L2 AS B ),
    Nums AS ( SELECT ROW_NUMBER() OVER(ORDER BY (SELECT NULL)) AS rownum
              FROM L3 ),
    Dates AS (
        SELECT TOP( DATEDIFF(day, @FromDate, @ToDate)   1 )
            DATEADD(day, rownum - 1, @FromDate) AS dateVal
        FROM Nums
    )

SELECT
    dateVal AS Date,
    CONVERT(Varchar(50), dateVal, 103) AS ShortDate,
    v.DayNames,
    'Full Session' AS Session,
    1 AS NoOfDays,
    CASE WHEN v.DayNames = 'Sunday' THEN '' ELSE 'Work Day' END AS Status,
    CASE WHEN v.DayNames = 'Sunday' THEN '' ELSE 'W' END AS StatusCode
FROM Dates
CROSS APPLY (VALUES (DATENAME(dw, dateVal) ) ) AS v(DayNames)