Блог

Я пытаюсь написать пользовательское утверждение / сопоставление, связанное с доменом, в spock или hamcrest, но я не уверен, как поступить.

Я пытался написать пользовательский Matcher в hamcrest, но пока это привело меня только к частичному решению.

Я ищу некоторые рекомендации относительно того, каким будет правильный курс в этом сценарии.

Объекты домена:

• resultMap имеет объектную карту < iLINE, IResult > — с каждой iLINE связан один INodeResult.
• В IResult есть 4 объекта multimap (Google Guava), которые необходимо проверить.

То, что я хотел бы сделать в своем тесте Спока, это что-то вроде:

 expect:
  that actualResultMap, matchesInAnyOrder(expectedResultMap)
  or
  that actualResultMap, matches(expectedResultMap) // Will only match if everything is in the same order.
  

Затем внутренний код будет оценивать каждую запись и выполнять соответствующие тесты для внутренних объектов.

До сих пор мне удалось написать часть кода, которая оценивает один набор multimap, но я не уверен, как связать мои тесты.

Пользовательский Сопоставитель:

 package com.ps.DE.Test.CustomMatcher

import org.hamcrest.BaseMatcher

class MultimapMatcher {

    /**
     * Checks all the entries in a Multimap with another
     * @param expected
     * @return Shows the failure only if the entries do not match or are not in the same order
     */
    static hasAllInOrder(final com.google.common.collect.Multimap expected){
        [
                matches: { actual ->
                    for(key in actual.keySet()){
                        if (actual.get(key) != expected.get(key)){
                            return false
                        }
                    }
                    return true
                },
                describeTo: { description ->
                    description.appendText("MultiMap entries to be ${expected}")
                },
                describeMismatch: { actual, description ->
                    description.appendText("were ${actual}")
                }
        ]   as BaseMatcher
    }

    /**
     * Checks all the entries in a Multimap with another
     * @param expected
     * @return Shows the failure only if the entries do not match
     */
    static hasAllInAnyOrder(final com.google.common.collect.Multimap expected){
        [
                matches: { actual ->
                    for(key in actual.keySet()){
                        if (!actual.get(key).containsAll(expected.get(key))) {
                            return false
                        }
                    }
                    return true
                },
                describeTo: { description ->
                    description.appendText("MultiMap entries to be ${expected}")
                },
                describeMismatch: { actual, description ->
                    description.appendText("were ${actual}")
                }
        ]   as BaseMatcher
    }
}
  

Тестирование пользовательского средства сопоставления:

 package com.ps.DE.Test.CustomMatcher

import com.google.common.collect.ArrayListMultimap
import com.google.common.collect.Multimap
import spock.lang.Specification

import static com.ps.DE.Test.CustomMatcher.MultimapMatcher.hasAllInAnyOrder
import static com.ps.DE.Test.CustomMatcher.MultimapMatcher.hasAllInOrder
import static org.hamcrest.Matchers.not
import static spock.util.matcher.HamcrestSupport.that


class MultimapMatcherSpec extends Specification {

    def "Test hasAllInOrder"() {
        def actual = ArrayListMultimap.create();

        // Adding some key/value
        actual.put "Fruits", "Apple"
        actual.put "Fruits", "Banana"
        actual.put "Fruits", "Pear"
        actual.put "Vegetables", "Carrot"

        Multimap<String, String> expected = ArrayListMultimap.create();

        // Adding some key/value
        expected.put("Fruits", "Apple");
        expected.put("Fruits", "Banana");
        expected.put("Fruits", "Pear");
        expected.put("Vegetables", "Carrot");

        expect:

        that actual, hasAllInAnyOrder(expected)
        that actual, hasAllInOrder(expected)
    }

    def "Test hasAllInAnyOrder"() {
        Multimap<String, String> actual = ArrayListMultimap.create();

        // Adding some key/value
        actual.put("Fruits", "Apple");
        actual.put("Fruits", "Banana");
        actual.put("Fruits", "Pear");
        actual.put("Vegetables", "Carrot");

        Multimap<String, String> expected = ArrayListMultimap.create();

        // Adding some key/value
        expected.put("Fruits", "Banana");
        expected.put("Fruits", "Apple");
        expected.put("Fruits", "Pear");
        expected.put("Vegetables", "Carrot");

        expect:
        that actual, hasAllInAnyOrder(expected)
        that actual, not(hasAllInOrder(expected))
    }
}
  

Любая помощь или рекомендации будут высоко оценены.

Зачем вам вообще нужны пользовательские сопоставления? Возможно, Spock и Groovy достаточно мощны, чтобы удовлетворить ваши потребности без пользовательских сопоставителей.

Чтобы сопоставить два Multimap объекта с одинаковым содержимым в одном и том же порядке, достаточно выполнить:

 expected:
actual == expected
  

Есть ли какая-то польза в добавлении гораздо большего количества кода к одному и тому же утверждению?

Для сопоставления в любом порядке это немного сложнее, но достаточно добавить метод сортировки (может быть извлечен и повторно использован в других тестовых классах). Это может выглядеть так:

 expected:
sortValues(actual) == sortValues(expected)
  

и сам метод:

 static Map<String, Collection<String>> sortValues(Multimap<String, String> multimap) {
    multimap.asMap().collectEntries {
        [it.key, it.value.sort(false)]
    }
}
  

Возможно, для лучшей читаемости спецификации sortValues() может иметь имя anyOrder() , которое сделало бы утверждение похожим:

 expect:
anyOrder(actual) == anyOrder(expected)
  

Затем внутренний код будет оценивать каждую запись и выполнять соответствующие
тесты для внутренних объектов.

Эта часть может быть реализована equals методом для каждого сравниваемого типа объекта.