Блог

Я пытаюсь перебирать диапазон ячеек, блокируя любую ячейку с содержимым, оставляя пустые ячейки незапертыми.

Когда я запускаю приведенный ниже код, результатом является блокировка всего листа. Если я добавлю оператор else, лист будет разблокирован. В принципе, независимо от последнего.оператор locked = (true, false) — это то, как завершается весь лист.

Изменение 1 Возможно ли, что у меня есть некоторые настройки вкл / выкл, которые мешают, поскольку я единственный, кто не может заставить что-либо из этого работать?

 Sub ProtectTheSheet()
Dim chCell As Range
Dim chRng As Range

'Clear the default status
ActiveSheet.Unprotect
Range("A7:I35").Locked = False

Set chRng = ActiveSheet.Range("A7:I35")

'Check cell value in body and lock cells with content
For Each chCell In chRng.Cells
    If chCell.Value <> "" Then Cells.Locked = True
Next chCell

ActiveSheet.Protect

End Sub
  

 Sub ProtectTheSheet()
    Dim chCell As Range
    Dim chRng As Range

    ActiveSheet.Unprotect
    Set chRng = ActiveSheet.Range("A7:I35")

    'Check cell value in body and lock cells with content
    For Each chCell In chRng.Cells
        chCell.Locked = (chCell.Value <> "")
    Next chCell

    ActiveSheet.Protect

End Sub
  

Вы можете попробовать это.

 Public Sub abc()
ActiveSheet.Unprotect Password:="1234"
ActiveSheet.Range("I8:I500, K8:K500, M8:M500, N8:N500").Cells.Locked = False
ActiveSheet.Protect Password:="1234"
End Sub
  

Проверьте это: http://www.mrexcel.com/archive/VBA/15950b.html

 Sub CellLocker()
Cells.Select
' unlock all the cells
Selection.Locked = false
' next, select the cells (or range) that you want to make read only, 
' here I used simply A1
Range("A1").Select
' lock those cells
Selection.Locked = true
' now we need to protect the sheet to restrict access to the cells. 
' I protected only the contents you can add whatever you want
ActiveSheet.Protect DrawingObjects:=false, Contents:=true, Scenarios:=false
End Sub
  

Если вы скажете Range(«A1»).Выберите, затем он блокирует только A1. Вы можете указать несколько ячеек, которые будут заблокированы, указав следующее:
A3: A12, D3:E12,J1: R13, W18
Это блокирует A3 до A12 и D3 до E12 и т.д.

Возможно, я что-то упускаю, но…

 Cells.Locked = True
  

…заблокирует все ячейки на активном листе. Если вы просто измените его на…

 chCell.Locked = True
  

… тогда это работает; Я думаю ?! Поскольку диапазон очень мал, вы также можете не разблокировать ячейки в начале, а вместо этого разблокировать ячейки во время их блокировки, например

 For Each chCell In chRng.Cells
    If chCell.Value <> "" Then 
    chCell.Locked = True
    Else
    chCell.Locked = False
    End If
Next chCell
  

Если вы новичок в VBA, я бы рекомендовал циклически перебирать код построчно, как описано в этом видео консультанта по Excel. Если вы переходите по коду, вы можете проверить «работает ли ячейка A7 так, как ожидалось?» … вместо того, чтобы просто видеть конечный продукт

Быстрый способ разблокировать непустые ячейки — использовать специальные ячейки, см. Ниже.

При моем тестировании этот код нормально обрабатывает объединенные ячейки, я думаю, это то, что генерирует вашу ошибку в коде Тима, когда он пытается обрабатывать каждую ячейку по отдельности (что, чтобы быть ясным, не является проблемой в коде Тима, он имеет дело с неожиданным результатом)

Вы также можете найти полезной эту мою статью о быстром методе определения диапазона разблокированных ячеек

 Sub Quicktest()
    Dim rng1 As Range
    Dim rng2 As Range
    On Error Resume Next
    Set rng1 = ActiveSheet.Range("A7:I35").Cells.SpecialCells(xlFormulas)
    Set rng2 = ActiveSheet.Range("A7:I35").Cells.SpecialCells(xlConstants)
    On Error GoTo 0
    ActiveSheet.Unprotect
    ActiveSheet.Range("A7:I35").Cells.Locked = False
    If Not rng1 Is Nothing Then rng1.Cells.Locked = True
    If Not rng2 Is Nothing Then rng2.Cells.Locked = True
    ActiveSheet.Protect
End Sub
  

Я знаю, что это старая тема, но я тоже застрял на этом некоторое время, и после некоторого тестирования в Excel 2013 вот к какому выводу я пришел, если ваш диапазон включает какую-либо объединенную ячейку

• Объединенные ячейки должны быть полностью включены в этот диапазон (например, слияние должно быть полностью в пределах диапазона блокировки / разблокировки
• Объединяемый диапазон может быть больше или, по крайней мере, точно соответствовать диапазону, соответствующему объединенным ячейкам. Если это именованный диапазон, который также работает.

Кроме того, вы не можете заблокировать / разблокировать ячейку, которая уже находится в пределах защищенного диапазона. Например, если вы запустите:

 public sub test()
   Sheet1.range("myNameRange").locked = true
   Sheet1.protect
end sub
  

Дважды это сработает в первый раз и завершится неудачей во второй раз. Поэтому вы должны снять защиту с целевого диапазона (или листа) раньше….

Если вы хотите защитить определенные ячейки любого конкретного Excel без защиты паролем, то вот решение:

 Sub ProtectingSheet()

  Workbooks.Open (cdocuments....)

  Dim mainworkBook As Workbook

  Set mainworkBook = ActiveWorkbook

  Worksheets(CellValue).Activate

  mainworkBook.Sheets("Sheet1").Range("A1:AA100").Locked = True

  Range(Cells(1, 2), Cells(1, 25)).Select
  Selection.Locked = False

  ActiveSheet.Protect

End Sub