Блог

Я пытаюсь написать загрузчик реального режима, и в настоящее время у меня возникают проблемы при попытке включить строку A20. Вот мой код до сих пор, я собираю с помощью NASM:

 [bits 16]

[global _start]

jmp _start

bios_print:
 lodsb
 test al, al
 jz bios_print_done
 mov ah, 0x0E
 mov bh, 0
 int 0x10
 jmp bios_print

bios_print_done:
 ret

a20_is_enabled:
 push ds
 push si
 push es
 push di

 xor ax, ax
 mov ds, ax
 mov si, BOOT_ID_OFFS

 mov ax, BOOT_ID_OFFS_PLUS_1MB_SEGM
 mov es, ax
 mov di, BOOT_ID_OFFS_PLUS_1MB_OFFS

 cmp word [es:di], BOOT_ID

 mov ax, 1
 jne a20_is_enabled_done

 mov ax, word [ds:si]
 xor ax, ax
 mov [ds:si], ax

 cmp word [es:di], BOOT_ID

 push ax
 xor ax, ax
 mov [ds:si], ax
 pop ax

 mov ax, 1
 jne a20_is_enabled_done

 mov ax, 0

a20_is_enabled_done:
 pop di
 pos es
 pop si
 pop ds

 ret

a20_enable_bios:
 mov ax, 0x2403
 int 0x15
 jc a20_enable_bios_failure
 test ah, ah
 jnz a20_enable_bios_failure

 mov ax, 0x2401
 int 0x15
 jc a20_enable_bios_failure
 test ah, ah
 jnz a20_enable_bios_failure

 mov ax, 1
 jmp a20_enable_bios_done

a20_enable_bios_failure:
 mov ax, 0

a20_enable_bios_done:
 ret

a20_enable:

 push si

 mov si, word MSG_A20_TRY_BIOS
 call bios_print

 pop si

 call a20_enable_bios

 test ax, ax
 jz a20_enable_failure

 call a20_is_enabled

 test ax, ax
 jnz a20_enable_success

a20_enable_failure:

 push si

 mov si, word MSG_A20_FAILURE
 call bios_print

 pop si

 mov ax, 0
 jmp a20_enable_done

a20_enable_success:

 push si

 mov si, word MSG_A20_SUCCESS
 call bios_print

 pop si

 mov ax, 1

a20_enable_done:
 ret

_start:
 xor ax, ax
 mov ds, ax

 cld

 cli

 push si

 mov si, word MSG_GREETING
 call bios_print

 pop si

 call a20_enable

 test ax, ax
 jz boot_error

 ; TODO

boot_error:
 jmp boot_error

BOOT_ID equ 0xAA55
BOOT_ID_OFFS equ 0x7DFE
BOOT_ID_OFFS_PLUS_1MB_SEGM equ 0xFFFF
BOOT_ID_OFFS_PLUS_1MB_OFFS equ BOOT_ID_OFFS   (0x1 << 20) - (BOOT_ID_OFFS_PLUS_1MB_SEGM << 4)

MSG_GREETING db 'Hello from the bootloader', 0xA, 0xD, 0
MSG_A20_TRY_BIOS db 'Trying to enable A20 line via BIOS interrupt', 0xA, 0xD, 0
MSG_A20_SUCCESS db 'Successfully enabled A20 line', 0xA, 0xD, 0
MSG_A20_FAILURE db 'Failed to enable A20 line', 0xA, 0xD, 0

times 510-($-$$) db 0
dw BOOT_ID
  

Проблема заключается в функции a20_is_enabled , которая должна проверять, включена ли линия A20 после a20_enable_bios того, как активировала ее через прерывание BIOS (я знаю, что это не надежно, здесь будет приведен дополнительный код). Когда я отлаживаю код , кажется , что все в порядке до тех пор, пока call a20_is_enabled . Затем процессор действительно выполняет ближний вызов для исправления адреса здесь, но обратный адрес не помещается в стек (что я проверил с помощью gdb). Таким образом, при ret выполнении in a20_is_enabled указатель инструкции устанавливается на некоторый мусорный адрес. Почему это так?

РЕДАКТИРОВАТЬ: обратите внимание, что ORG 0x7C00 в начале моего ассемблерного кода его нет. Это потому, что я сначала создаю файл elf, чтобы я мог отлаживать свой код с помощью gdb, и это плохо работает ORG , поэтому я на самом деле делаю это:

 nasm -f elf32 -g -F dwarf boot.asm -o boot.o
ld -Ttext=0x7c00 -melf_i386 boot.o -o boot.elf
objcopy -O binary boot.elf boot.bin
  

Обычно этот вопрос можно закрыть, поскольку он вызван типографской ошибкой, но ошибка не обязательно очевидна на первый взгляд. В отладчике нужно внимательно следить за выполняемыми инструкциями.

Это заставило меня почесать голову, так как, когда я посмотрел в отладчике последовательность:

  push ds
 push si
 push es
 push di

 ; Snip other code

 pop di
 pos es
 pop si
 pop ds
 ret
  

только показал, что процессор выполняет 3 POP s и a ret , когда явно есть 4 POP инструкции. Поскольку процессор не выполняет достаточно всплывающих окон, адрес возврата неверен и ret возвращается в неправильную часть памяти и вызывает неожиданное поведение.

Проблема довольно тривиальна, и из-за невезения инструкция создается без ошибок, но это не та инструкция, которую вы хотите. Если вы посмотрите внимательно, это виновник:

  pos es
  

Здесь опечатка. POS должно быть POP . Сначала мой мозг этого не уловил. pos обрабатывается как метка и es является переопределением сегмента, поэтому может отображаться в строке самостоятельно. Это привело к созданию инструкции es pop si .

Очевидно, что исправление состоит в том, чтобы изменить его на:

  pop es