Блог

У меня есть этот код, но он работает только для моей первой строки. Предполагается посмотреть, установлен ли флажок на B, C или D, и если это так, дата имя пользователя автоматически заполнят F и G.

вот изображение моей таблицы:

Вот как выглядит мой код:

 Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Range("B2") Or Range("C2") Or Range("D2") = True Then
Range("G2").Value = Environ("Username")
Range("F2").Value = Date
Else
Range("F2:G2").ClearContents
End If
End Sub
  

Введите этот код в обычный модуль, установите все флажки и щелкните правой кнопкой мыши >> назначить макрос, затем выберите ReviewRows .

Проверка будет выполняться при каждом нажатии флажка — немного накладных расходов, поскольку все строки будут проверены, но это не должно иметь большого значения.

 Sub ReviewRows()
    Dim n As Long
    For n = 1 To 100 'for example
        With Sheet1.Rows(n)
            If Application.CountIf(.Cells(2).Resize(1, 3), "TRUE") > 0 Then
                If Len(.Cells(6).Value) = 0 Then 'only enter if currently empty?
                    .Cells(6) = Date
                    .Cells(7) = Environ("Username")
                End If
            Else
                .Cells(6).Resize(1, 2).ClearContents
            End If
        End With
    Next n
End Sub
  

Если вы хотите быть более точным, тогда Application.Caller вам будет указано имя флажка, который был нажат, и вы можете использовать его, чтобы найти соответствующую строку для проверки с помощью linkedCell .

 Sub ReviewRows()
    Dim n As Long, shp As CheckBox, c As Range, ws As Worksheet
    
    Set ws = ActiveSheet
    On Error Resume Next 'ignore error in case calling object is not a checkbox
    Set shp = ActiveSheet.CheckBoxes(Application.Caller) 'get the clicked checkbox
    On Error GoTo 0 'stop ignoring errors
    
    If Not shp Is Nothing Then          'got a checkbox ?
        If shp.LinkedCell <> "" Then    'does it have a linked cell ?
            With ws.Range(shp.LinkedCell).EntireRow
                If Application.CountIf(.Cells(2).Resize(1, 3), "TRUE") > 0 Then
                    If Len(.Cells(6).Value) = 0 Then 'only enter if currently empty?
                        .Cells(6) = Date
                        .Cells(7) = Environ("Username")
                    End If
                Else
                    .Cells(6).Resize(1, 2).ClearContents
                End If
            End With
        End If 'has linked cell
    End If 'was a checkbox
End Sub

  

Однако эта оценка зависит от точного расположения вашего флажка

Вам предстоит пройти долгий путь! К сожалению, If Range("B2") Or Range("C2") Or Range("D2") = True Then восстановлению не подлежит. На самом деле, вся ваша концепция такова.

Начните с концепции: технически говоря, флажков нет на рабочем листе. Они находятся на слое, который накладывается на рабочий лист. Они не вызывают событие рабочего листа и не реагируют на события рабочего листа. Хорошо, что у них есть свои собственные.

If Range("B2") Or Range("C2") Or Range("D2") = True Then объединяет Range с Range.Value . Один — это объект (ячейка), другой — одно из свойств объекта. Итак, чтобы вставить смысл в ваш синтаксис, он должен был бы читать, например, If Range("B2").Value = True Or Range("C2").Value = True Or Range("D2").Value = True Then . Однако это не сработает, потому что триггер неверен. Событие Worksheet_Change не срабатывает, когда флажок изменяет значение ячейки, а событие SelectionChange слишком распространено, чтобы позволить ему выполняться без разбора в надежде, что иногда оно будет правильным (например, сломанные часы, которые показывают правильное время два раза в день).

Поэтому ответ заключается в том, чтобы зафиксировать событие щелчка флажка.

 Private Sub CheckBox1_Click()
    If CheckBox1.Value = vbTrue Then
        MsgBox "Clicked"
    End If
End Sub
  

Все, что вы хотите сделать, когда флажок установлен, должно быть сделано там, где теперь отображается сообщение. Вы также можете предпринять действия, когда флажок снят.