Блог

Главная - Вопросы по программированию - Как я могу использовать send receive для нескольких значений в Erlang?

Как я могу использовать send receive для нескольких значений в Erlang?

#erlang #distributed-computing #distributed-system #erlang-otp #erlang-ports

#erlang #распределенные вычисления #распределенная система #erlang-otp #erlang-порты

Вопрос:

У меня есть следующие циклы:

 for( i = 1 ; i < V ; i   )
{
    i sends "hi" to arr[i]
}

for( i = 1 ; i <arr.size ; i   )
{
    if arr[i] receives "hi"
    {
        print "bye"
    }
}

Как я могу реализовать эти коды в erlang?

Я понял простой пинг и понг, но я хочу создать этот код параллельно, чтобы сбалансировать нагрузку. Я несколько запутался в части реализации цикла.

Комментарии:

1. Вы должны использовать рекурсивные функции или функции высокого порядка. Я мог бы написать код для вас, но это, вероятно, не принесет вам пользы. Я рекомендую вам сначала проверить здесь: learnyousomeerlang.com/recursion

2. Спасибо за ваш комментарий. нужно ли мне создавать узлы или простой код отправки получения будет работать? Цикл довольно прост с помощью рекурсии, да. Но не приведет ли это к некоторому последовательному поведению?

3. Должен ли я использовать spawn?

4. Да, в зависимости от того, какого параллелизма вы хотите достичь, вам, вероятно, потребуется запускать процессы внутри рекурсивных функций или функций высокого порядка, и для этих процессов потребуется оператор receive . Создание узлов, вероятно, слишком много, но опять же… Я не знаю конкретных требований вашего упражнения.

5. Тогда Spawn должен работать, я хочу иметь код быстрее, чем последовательный, да, узлов может быть слишком много. Еще раз, большое спасибо!!

Ответ №1:

Вот пример того, что вы можете сделать:

 -module(a).
-compile(export_all).

worker() ->
    receive
        {hi, From} ->
            From ! {bye, self()},
            worker();
        stop ->
            io:format("Worker ~w terminated.~n", [self()]);
        _Other ->
            io:format("Bad message received by worker: ~w~n", [self()]),
            worker()
    end.


create_workers(N) ->
    create_workers(N, _Pids=[]).

create_workers(0, Pids) -> Pids;
create_workers(N, Pids) ->
    Pid = spawn(a, worker, []),
    create_workers(N-1, [Pid|Pids]).

test()->
    N = 4,
    Workers = create_workers(N),
    RandNum1 = rand:uniform(N),
    RandNum2 = rand:uniform(N),
    Worker1 = lists:nth(RandNum1, Workers),
    Worker2 = lists:nth(RandNum2, Workers),

    Worker1 ! hello,
    Worker1 ! {hi, self()},

    Worker2 ! {xxxx, self()},
    Worker2 ! {hi, self()},

    Results = get_results(2, _Acc=[]),
    io:format("Worker results: ~w~n", [Results]),
    terminate(Workers).


get_results(0, Acc) -> Acc;
get_results(N, Acc) ->
    Result = receive
                 {Msg, _From} -> Msg
             end,
    get_results(N-1, [Result|Acc]).

terminate(Workers) ->
    lists:foreach(fun(Worker) -> Worker ! stop end,
            Workers).

В оболочке:

 6> c(a).    
a.erl:2: Warning: export_all flag enabled - all functions will be exported
{ok,a}

7> a:test().
Worker results: [bye,bye]
Bad message received by worker: <0.96.0>
Bad message received by worker: <0.99.0>
Worker <0.96.0> terminated.
Worker <0.99.0> terminated.
Worker <0.98.0> terminated.
Worker <0.97.0> terminated.
ok