Блог

Главная - Вопросы по программированию - Массив с XSLT 1.0

Массив с XSLT 1.0

#arrays #xml #xslt #xslt-1.0

#массивы #xml #xslt #xslt-1.0

Вопрос:

У меня есть простой массив ниже

 <xsl:template match="/">
    <xsl:variable name="array">
        <Item>One</Item>
        <Item>Two</Item>
        <Item>Three</Item>
    </xsl:variable>
    <html>
        <body>
            <xsl:value-of select="$array"/>
        </body>
    </html>
</xsl:template>

Который отображает

 OneTwoThree

Однако, когда я пытаюсь

 <xsl:value-of select="$array[0]"/>

Вся страница разрывается

Есть какие-нибудь идеи, как я могу получить доступ к «Единице» в моем массиве?

Ответ №1:

Во-первых, в XSLT 1.0 нет массивов. Ваша переменная представляет собой фрагмент результирующего дерева с 3 Item дочерними элементами.

Фрагменты дерева результатов не могут быть проанализированы напрямую; вам необходимо сначала преобразовать их в набор узлов, используя функцию расширения, поддерживаемую вашим процессором, например:

 <xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/">
    <xsl:variable name="array">
        <Item>One</Item>
        <Item>Two</Item>
        <Item>Three</Item>
    </xsl:variable>
    <html>
        <body>
            <xsl:value-of select="exsl:node-set($array)/Item[1]"/>
        </body>
    </html>
</xsl:template> 

</xsl:stylesheet>

В качестве альтернативы вы можете обойти это ограничение, проанализировав таблицу стилей напрямую:

 <xsl:template match="/">
    <xsl:variable name="array">
        <Item>One</Item>
        <Item>Two</Item>
        <Item>Three</Item>
    </xsl:variable>
    <html>
        <body>
            <xsl:value-of select="document('')//xsl:variable[@name='array']/Item[1]"/>
        </body>
    </html>
</xsl:template>

Обратите внимание, что нумерация узлов начинается с 1, а не с 0.