Блог

Я написал процедуру Nim, взяв в качестве var параметров два объекта. Каждый из них представляет собой объект с int полем level . Прежде чем приступить к реальной работе процедуры, я хочу упорядочить параметры по порядку, по которому они больше level , поэтому я делаю это:

 proc subroutine(param1: var MyObject, param2: var MyObject) =
  var large: ptr MyObject = param1.addr
  var small: ptr MyObject = param2.addr

  # If in wrong order by level, swap large and small
  if large.level < small.level:
    large = param2.addr
    small = param1.addr

  # The rest of the proc references, only variables large and small, e.g.,
  large.level  = 1
  small.level  = 2
  

Кажется, это работает для моего приложения, но я замечаю, что в документации Nim этот ptr тип называется «небезопасным», и его предлагается использовать только для низкоуровневых операций. Существует «безопасный» ссылочный тип ref , и его рекомендуется использовать ref , если вы действительно не хотите выполнять ручное управление памятью.

Я не хочу выполнять ручное управление памятью, и я хочу, чтобы сборщик мусора Nim обрабатывал память для этих параметров для меня, но я не вижу способа обеспечить безопасность ref для двух параметров.

Я действительно хочу иметь возможность написать алгоритм (который значительно сложнее, чем простой код, который я показал) в терминах переменных large and small , а не param1 and param2 . В противном случае, если я могу ссылаться только на параметры param1 и param2 , не создавая для них эти псевдонимы, мне пришлось бы копировать и вставлять один и тот же алгоритм дважды, чтобы отдельно обрабатывать случаи param1.level < param2.level и param1.level >= param2.level .

Есть ли более идиоматический способ Nim сделать что-то подобное, без использования ptr типа?

Вы не можете превратить безопасный объект в небезопасный и наоборот, кроме как выполнив копирование объекта.

Обычные переменные хранятся в стеке и, следовательно, будут уничтожены, когда их область действия функции существует, но ссылка может быть сохранена в глобальной переменной и доступна позже. Если бы это было возможно, чтобы сделать его безопасным, компилятору / языку нужно было бы знать какой-то способ извлечения переменной из стека, чтобы она оставалась действительной после существования ее области видимости, или выполнить копирование вручную за вашей спиной, или какую-то другую волшебную вещь.

Это также причина, по которой небезопасно использовать адрес переменной. Вы не можете гарантировать его срок службы, потому что вы можете сохранить этот адрес где-нибудь еще и попытаться использовать его позже. Однако, с точки зрения гарантий памяти, эти переменные должны быть активными, по крайней мере, на время вашего вызова proc, поэтому должно быть безопасно использовать эти псевдонимы адресов в этом процессе, не беспокоясь.

Тем не менее, вы можете переписать свой код, чтобы использовать промежуточный прокси-процесс, который выполняет проверку и, таким образом, передает правильные переменные в каждом слоте. Промежуточный процесс гарантирует, что одна из переменных всегда будет большой, и вы можете избежать использования небезопасных ссылок:

 type
  MyObject = object
    level: int

proc subroutine_internal(large: var MyObject, small: var MyObject) = 
  assert large.level >= small.level
  large.level  = 1
  small.level  = 2

proc subroutine(param1: var MyObject, param2: var MyObject) =
  if param1.level < param2.level:
    subroutine_internal(param2, param1)
  else:
    subroutine_internal(param1, param2)

proc main() =
  var
    a = MyObject(level: 3)
    b = MyObject(level: 40)

  subroutine(a, b)
  echo a, b

main()
  

 type
  MyObject = object
    level: int

proc subroutine(param1, param2: var MyObject) =
  if param1.level > param2.level:
    swap(param1, param2)
  echo param1.level
  echo param2.level

var
  p1 = MyObject(level: 7)
  p2 = MyObject(level: 3)

subroutine(p1, p2)
p2.level = 13
subroutine(p1, p2)
  

Для этого случая в Nim есть специальная процедура swap(). Параметры Var передаются внутри как указатели, поэтому при передаче параметров копирование не требуется, и swap должен выполнять копирование как можно более оптимально.

Конечно, могут быть случаи, когда использование объектов ref вместо объектов value может иметь преимущества. Ссылки Nim являются управляемыми указателями. Вы можете найти больше информации в руководствах, и мой находится по адресу http://ssalewski.de/nimprogramming.html#_value_objects_and_references .