Как я могу отличить свойства TDateTime от двойных свойств с помощью RTTI?

#delphi #rtti #tdatetime

Вопрос:

Используя систему RTTI в Delphi 2010, есть ли какой-либо способ узнать, является ли свойство TDateTime? В настоящее время он обрабатывает его как двойной всякий раз, когда я перезваниваю asVariant, а также если я проверяю тип свойства. Связано ли это с тем, что он может видеть только базовый тип? (TDateTime = double)

1. Ну, дата / время всегда является двойным, в котором целая часть представляет дни, а дробная часть представляет минуты и секунды (как часть дня)

2. Я понимаю, что технически это double, но могу ли я каким-либо образом использовать RTTI, чтобы проверить, определено ли оно как TDateTime изначально

Ответ №1:

Попробуйте проверить Name свойство TRttiProperty.PropertyType

У меня нет Delphi 2010, но это работает в XE.

 {$APPTYPE CONSOLE}

uses
  SysUtils,
  Classes,
  Rtti;

type
  TMyClass =class
  private
    FDate: TDateTime;
    FProp: Integer;
    FDate2: TDateTime;
    FDate1: TDateTime;
  public
   property Date1 : TDateTime read FDate1  Write FDate1;
   property Prop : Integer read FProp  Write FProp;
   property Date2 : TDateTime read FDate2  Write FDate2;
  end;

var
 ctx : TRttiContext;
 t :  TRttiType;
 p :  TRttiProperty;
begin
 ctx := TRttiContext.Create;
 try
   t := ctx.GetType(TMyClass.ClassInfo);
   for p in  t.GetProperties do
    if CompareText('TDateTime',p.PropertyType.Name)=0 then
     Writeln(Format('the property %s is %s',[p.Name,p.PropertyType.Name]));
 finally
   ctx.Free;
 end;
  Readln;
end.

этот код возвращает

 the property Date1 is TDateTime
the property Date2 is TDateTime

Ответ №2:

Ключевым моментом здесь при определении типа является директива type . Эти два определения различны:

 Type
  TDateTime = Double; // here p.PropertyType.Name returns Double

but

Type
  TDateTime = type Double; // here p.PropertyType.Name returns TDateTime

or 

Type
  u8 = type Byte; // here p.PropertyType.Name returns u8

but

Type
  u8 = Byte; // here p.PropertyType.Name returns Byte !

1. Очевидно, что OP не объявлял рассматриваемые типы, поэтому технически это не ответ, но вы совершенно правы, и это дополнительное объяснение является хорошей информацией. 1