Блог

Итак, цель этого макроса — открыть определенный файл, чтобы затем скопировать из этого файла и вставить обратно в исходную книгу, где хранится макрос.

Стоит отметить элементы, которые делают этот макрос немного уникальным:

Workbook A (wbDestination) — Excel с несколькими листами, где будет сохранен макрос и куда будет вставлена информация из Workbook B. Расположение пути к файлу для книги B будет меняться ежемесячно, поэтому я создал функцию в этой книге A, где макрос сможет успешно находить путь к файлу, чтобы соответствовать ежемесячному изменению местоположения пути к файлу. Мне нужно, чтобы исходные данные из книги B были вставлены в «Лист2» в книге A. Расположение пути к файлу книги B находится в ячейке C2 на листе под названием «Макросы» в книге A.

Workbook B (wbSourceData) — Excel с несколькими листами, где будут храниться исходные данные, которые мне нужно скопировать и вставить в Workbook A. Исходные данные, которые я буду копировать, находятся на втором листе.

 Sub CopyPaste()

    Dim wbSourceData As Workbook
    Dim wbDestination As Workbook
    Dim wsSourceData As Worksheet
    Dim wsDestination As Worksheet
    Dim strFName As String
    

    Set wbDestination = ThisWorkbook
    Set wsDestination = wbDestination.Sheets("Sheet2")
    
    strFName = wbDestination.Worksheets("Macros").Range("C2").Value
    
    Set wbSourceData = Workbooks.Open(strFName)
    Set wsSourceData = wbSourceData.Worksheets(2)
    
    
    wsSourceData.Range("A2").Select
        Range(Selection, Selection.End(xlToRight)).Select
        Range(Selection, Selection.End(xlToRight)).Select
        Range(Selection, Selection.End(xlDown)).Select
        Selection.Copy
    wsDestination.Select
        Range("A4").Select
        Selection.PasteSpecial Paste:=xlPasteValues
    
    wbSourceData.Close SaveChanges:=False
    
End Sub
  

Некоторые другие вещи, на которые следует обратить внимание. Я успешно могу открыть книгу B в этой функции, но затем макрос умирает, когда я пытаюсь скопировать данные. Ошибка, которую я получаю в «Ошибка времени выполнения ‘1004’: ошибка выбора метода класса диапазона». Я также хочу использовать функции выбора диапазона xlToRight (дважды) и xlDown в рабочей книге A, потому что количество строк этих исходных данных будет меняться ежемесячно, и это лучший способ захватить весь диапазон. Мне понадобятся исходные данные из книги B, которые будут вставлены обратно в книгу A в качестве значений вставки.

Я новичок в VBA, поэтому все, что необходимо для исправления этого макроса, пожалуйста, ELI5, спасибо! Я действительно ценю это!

Очень красиво настроен. Мне нравится, с какой тщательностью вы подошли к названию. Это очень полезно. Но когда дело дошло до копирования / вставки, вы не читали главу, где говорилось «вам не нужно ничего выбирать». Вот улучшенная версия этой части кода.

 With wsSourceData
    ' last used cell in row 2 looking from right to left
    Cl = .Cells(2, .Columns.Count).End(xlToLeft).Column
    ' last used row in column A looking from bottom up
    Rl = .Cells(.Rows.Count, "A").End(xlUp).Row
    Set Rng = .Range(.Cells(2, "A"), .Cells(Rl, Cl))
End With
Rng.Copy Destination:=wsDestination.Range("A4")
  

Как вы видите, задача состоит в том, чтобы указать Range . Конечно, Selection объект — это диапазон. Excel использует его для передачи в свой бэк-офис того, что пользователь нажал на экране. Он не очень хорошо подходит для чего-либо еще и поэтому используется вместо диапазона всякий раз, когда используется. Следовательно, идите прямо к диапазону, если это тот диапазон, который вам нужен.

xlToRight ищет следующую пустую ячейку справа. xlToLeft ищет первую использованную ячейку справа. Ваш код перепрыгивает через пустую ячейку, чтобы найти конец. То же самое для просмотра сверху вниз или с конца вверх. Я надеюсь, что справа больше нет заполненных ячеек, которые вы, на самом деле, хотите исключить, или сверху вниз. Если это так, переменные Rl и Cl должны быть найдены с использованием используемого вами кода. Настройка диапазона будет выполняться с теми же переменными, установленными по-другому.

Вот объявления, которые я добавил к тем, которые у вас уже есть.

 Dim Rng             As Range
Dim Cl              As Long                 ' last used column
Dim Rl              As Long                 ' last used row