Блог

Мне нужно периодически сохранять кэш на диск, каждые 500 мс, как я могу это сделать?

Код, который я пробовал, не скомпилирован должным образом. Кроме того, кажется, что asyncCheck следует использовать для проверки ошибок.

 import tables, os, asyncdispatch

var cache = init_table[string, int]()

proc save(cache: Table[string, int]): Future[void] {.async.} =
  echo cache

addTimer(
  timeout = 500, oneshot = false, cb = proc() = discard cache.save()
)

for i in (0..3):
  cache["a"] = i
  echo cache
  sleep 1000
  

Я думаю, что это то, что вам нужно

 import tables,asyncdispatch,strformat    

#global, GC'd variable, careful!         
var cache = initTable[string, int]()    
     
proc save(){.async.} =                                  
  while true:    
    echo amp;"writing cache:{cache}"    
    await sleepAsync(500)    

#just some fake data sources         
proc write1(){.async.} =  
  await sleepAsync(900)
  for i in 0..99:                                            
    cache["a"]=i     
    await sleepAsync(20)
#that happen at various rates
proc write2(){.async.} = 
  for i in 0..99:
     cache["b"]=i
     await sleepAsync(33)

#asyncCheck when we're not interested in the Future from a proc
#it will raise an Exception if the proc has an error
asyncCheck save() #save starts running asynchronously

echo "but we can still run other code"

waitFor:          #blocks here until both write1 and write2 finish            
  write1() and write2()

echo "writing is done but save is still running"
cache["c"]=17

#os.sleep would block the whole thread, including save so instead
waitFor(sleepAsync(500)) #wait for save to echo one more time

echo "quit"
  

выводит что-то вроде:

 writing cache:{:}
but we can still run other code
writing cache:{"b": 15}
writing cache:{"b": 30, "a": 4}
writing cache:{"b": 45, "a": 29}
writing cache:{"b": 59, "a": 54}
writing cache:{"b": 74, "a": 78}
writing cache:{"b": 89, "a": 99}
writing is done but save is still running
writing cache:{"b": 99, "c": 17, "a": 99}
quit