Блог

Запуск нашего программного обеспечения запустит оболочку Tcl в терминале, затем мы сможем выполнить серию команд tcl в этой оболочке Tcl, создав файл сценария tcl. Но команды tcl внутри файла сценария tcl не будут напечатаны в оболочке Tcl, поэтому мы не можем видеть, какие команды были выполнены исходным кодом сценария tcl.

Итак, мой вопрос в том, есть ли какая-либо конфигурация Tcl, которая может распечатывать команды в сценарии, когда сценарий был исходным.

Ниже приведен пример сценария tcl

 # sample.tcl, composed of 3 tcl commands:
read designfile
analyze
write output
  

Если мы интерактивно выполним 3 команды tcl в оболочке Tcl, результат будет выглядеть как:

 Tcl> read designfile
Info: reading designfile
Info: size: 128k
...
...
Tcl> analyze
Info: analyzing designfile
Info: 108 modules need to be analyzed
...
...
Tcl> write output
Info: analyzed data been written into file "output"
  

Если мы отправим этот сценарий tcl в оболочку Tcl, результат будет:

 Tcl> source sample.tcl
Info: reading designfile
Info: size: 128k
...
...
Info: analyzing designfile
Info: 108 modules need to be analyzed
...
...
Info: analyzed data been written into file "output"
  

Мы ожидаем, что результат будет таким, как показано ниже, когда мы отправим сценарий.

 Tcl> source sample.tcl
> read designfile
Info: reading designfile
Info: size: 128k
...
...
> analyze
Info: analyzing designfile
Info: 108 modules need to be analyzed
...
...
> write output
Info: analyzed data been written into file "output"
  

Большое спасибо Доналу! Основываясь на его предложении, наконец, я получил команду трассировки, как показано ниже, чтобы удовлетворить мое требование.

 proc print {args} {
    set cmd [lindex $args 0]
    puts stdout "$> $cmd"
}

trace add execution source enterstep print
  

Это задание для трассировки выполнения. Они могут применяться ко всем видам команд Tcl, а не только к процедурам.

 trace add execution source enterstep {apply {{cmd op} {
    # Trim multiline commands down a bit; I find this helps me at least!
    regsub {n.*} $cmd ... cmd
    # Print what's being run
    puts "EXECUTE: $cmd"
}}}
source thefile.tcl
  

Обратите внимание, что это может напечатать намного больше, чем вы ожидаете! Вот более сложная версия, которая печатает только самый внешний уровень выполнения.

 # Called before [source] starts running
trace add execution source enter {apply {args {
    global SOURCE_LEVEL
    if {![info exists SOURCE_LEVEL]} {
        set SOURCE_LEVEL [info level]
    }
}}}
# Called after [source] finishes running
trace add execution source leave {apply {args {
    global SOURCE_LEVEL
    if {$SOURCE_LEVEL == [info level]} {
        unset SOURCE_LEVEL
    }
}}}
# Called for every command called while [source] is running
trace add execution source enterstep {apply {{cmd op} {
    global SOURCE_LEVEL
    if {$SOURCE_LEVEL == [info level]} {
        regsub {n.*} $cmd "..." cmd
        puts "EXECUTE: $cmd"
    }
}}}