Блог

Я хочу отключить кнопку X в форме в зависимости от условия. Итак, что-то вроде:

 If Boolean Then 
   ControlBox = False
Else
   ControlBox = True
End If
  

Когда я пытаюсь использовать это, я получаю сообщение об ошибке, в котором говорится, что Visual Basic не поддерживает эту функцию.
Это будет сделано при загрузке формы, и логическое значение не изменится.

Я искал этот форум, но не могу найти ответ, соответствующий моим потребностям.

Заранее спасибо.

Похоже, вы пытаетесь установить свойство ControlBox во время выполнения. Как вы видели, вы не можете этого сделать. Однако, с помощью небольшой магии API вы можете выполнить эту задачу:

 Option Explicit

Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function SetWindowPos Lib "user32" (ByVal hWnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long

Private Const WS_SYSMENU = amp;H80000
Private Const GWL_STYLE = (-16)
Private Const SWP_FRAMECHANGED = amp;H20
Private Const SWP_NOMOVE = amp;H2
Private Const SWP_NOZORDER = amp;H4
Private Const SWP_NOSIZE = amp;H1

Private Property Let ControlBoxVisible(ByVal Value As Boolean)
   Dim style As Long
   
   style = GetWindowLong(Me.hWnd, GWL_STYLE)
   style = IIf(Value, style Or WS_SYSMENU, style And Not WS_SYSMENU)
   SetWindowLong Me.hWnd, GWL_STYLE, style
   SetWindowPos Me.hWnd, 0, 0, 0, 0, 0, SWP_FRAMECHANGED Or SWP_NOMOVE Or SWP_NOZORDER Or SWP_NOSIZE
End Property
  

И тогда вы бы использовали ее следующим образом:

 Private Sub Form_Load()
   ControlBoxVisible = False
End Sub
  

Использование вызовов API. Взгляните на кнопку включения / выключения форм для закрытия

Существует архивированный файл проекта с исходным кодом.