Блог

Как использовать функцию terraform setproduct с более чем 2 списками в приведенном ниже сценарии или есть какой-либо другой способ достижения конечного результата.

В main.tf файл, в котором у меня есть следующие данные.

 $ cat main.tf
variable "nodes" {
  default = ["1", "2", "3"]
}

variable "ebs_volumes" {
  default = [
    {
      ebs_name = "/dev/xdba"
      ebs_size = "50"
      ebs_type = "gp2"
    },
    {
      ebs_name = "/dev/xdbb"
      ebs_size = "20"
      ebs_type = "gp2"
    }
  ]
}

locals {
  ebs_name = [for i in var.ebs_volumes : i.ebs_name]
  ebs_size = [for i in var.ebs_volumes : i.ebs_size]
  ebs_type = [for i in var.ebs_volumes : i.ebs_type]
}

locals {
  node_disks = { for pair in setproduct(var.nodes, local.ebs_name) : "${pair[0]}:${pair[1]}" => {
    node_index = pair[0]
    ebs_name   = pair[1]
    ebs_size   = [for i in var.ebs_volumes : i.ebs_size]
    ebs_type   = [for i in var.ebs_volumes : i.ebs_type]
  } }
}

output "combined" {
  value = local.node_disks
}
  

Когда я запускаю terraform apply, я получаю следующий результат

     $ terraform apply

Apply complete! Resources: 0 added, 0 changed, 0 destroyed.

Outputs:

combined = {
  "1:/dev/xdba" = {
    "ebs_name" = "/dev/xdba"
    "ebs_size" = [
      "50",
      "20",
    ]
    "ebs_type" = [
      "gp2",
      "gp2",
    ]
    "node_index" = "1"
  }
  "1:/dev/xdbb" = {
    "ebs_name" = "/dev/xdbb"
    "ebs_size" = [
      "50",
      "20",
    ]
    "ebs_type" = [
      "gp2",
      "gp2",
    ]
    "node_index" = "1"
  }
  "2:/dev/xdba" = {
    "ebs_name" = "/dev/xdba"
    "ebs_size" = [
      "50",
      "20",
    ]
    "ebs_type" = [
      "gp2",
      "gp2",
    ]
    "node_index" = "2"
  }
  "2:/dev/xdbb" = {
    "ebs_name" = "/dev/xdbb"
    "ebs_size" = [
      "50",
      "20",
    ]
    "ebs_type" = [
      "gp2",
      "gp2",
    ]
    "node_index" = "2"
  }
  "3:/dev/xdba" = {
    "ebs_name" = "/dev/xdba"
    "ebs_size" = [
      "50",
      "20",
    ]
    "ebs_type" = [
      "gp2",
      "gp2",
    ]
    "node_index" = "3"
  }
  "3:/dev/xdbb" = {
    "ebs_name" = "/dev/xdbb"
    "ebs_size" = [
      "50",
      "20",
    ]
    "ebs_type" = [
      "gp2",
      "gp2",
    ]
    "node_index" = "3"
  }
}
  

Вместо этого я хочу иметь возможность получить результат, как показано ниже (код psudo):

 combined = {
  "1:/dev/xvdb" = {
    "disk_dev_path" = "/dev/xvda"
    "node_name" = "1"
    "disk_size" = "10"
    "disk_type" = "gp2"
  }
  "1:/dev/xvdc" = {
    "disk_dev_path" = "/dev/xvdb"
    "node_name" = "1"
    "disk_size" = "30"
    "disk_type" = "gp2"
  }
  "2:/dev/xvdb" = {
    "disk_dev_path" = "/dev/xvda"
    "node_name" = "2"
    "disk_size" = "10"
    "disk_type" = "gp2"
  }
  "2:/dev/xvdc" = {
    "disk_dev_path" = "/dev/xvdb"
    "node_name" = "2"
    "disk_size" = "30"
    "disk_type" = "gp2"
  }
  "3:/dev/xvdb" = {
    "disk_dev_path" = "/dev/xvda"
    "node_name" = "3"
    "disk_size" = "10"
    "disk_type" = "gp2"
  }
  "3:/dev/xvdc" = {
    "disk_dev_path" = "/dev/xvdb"
    "node_name" = "3"
    "disk_size" = "30"
    "disk_type" = "gp2"
  }
}
  

Как этого добиться?

Мне это нужно для того, чтобы использовать это в for_each для создания экземпляров ec2 и томов ebs и прикреплять их соответственно всякий раз, когда пользователь добавляет входные данные в переменную, используя наш модуль ec2.

Если вы можете, возможно, вы могли бы использовать для этого двойной цикл for с flatten . Мне это кажется более естественным.

Ниже приведен рабочий пример:

 variable "nodes" {
  default = ["1", "2", "3"]
}

variable "ebs_volumes" {
  default = [
    {
      ebs_name = "/dev/xdba"
      ebs_size = "50"
      ebs_type = "gp2"
    },
    {
      ebs_name = "/dev/xdbb"
      ebs_size = "20"
      ebs_type = "gp2"
    }
  ]
}

locals {

    node_disks2 = {for idx, value in flatten([for node in var.nodes: 
                   [for volume in var.ebs_volumes:
                    { 
                        node_index = node
                        ebs_name   = volume.ebs_name
                        ebs_size   = volume.ebs_size
                        ebs_type   = volume.ebs_type
                   }]
               ]): idx => value}
}

output "combined" {
  value = local.node_disks2
}
  

Выходной сигнал:

 ombined = {
  "0" = {
    "ebs_name" = "/dev/xdba"
    "ebs_size" = "50"
    "ebs_type" = "gp2"
    "node_index" = "1"
  }
  "1" = {
    "ebs_name" = "/dev/xdbb"
    "ebs_size" = "20"
    "ebs_type" = "gp2"
    "node_index" = "1"
  }
  "2" = {
    "ebs_name" = "/dev/xdba"
    "ebs_size" = "50"
    "ebs_type" = "gp2"
    "node_index" = "2"
  }
  "3" = {
    "ebs_name" = "/dev/xdbb"
    "ebs_size" = "20"
    "ebs_type" = "gp2"
    "node_index" = "2"
  }
  "4" = {
    "ebs_name" = "/dev/xdba"
    "ebs_size" = "50"
    "ebs_type" = "gp2"
    "node_index" = "3"
  }
  "5" = {
    "ebs_name" = "/dev/xdbb"
    "ebs_size" = "20"
    "ebs_type" = "gp2"
    "node_index" = "3"
  }
}