Блог

Я пытаюсь сгенерировать JSON из SQL с помощью PL / JSON

 declare 
      customer json_list := json_list();
      product json_list;

begin
  customer:= json_dyn.executeList('SELECT DISTINCT
  A.customer_id,
  A.customer_name,
  FROM customer A
  WHERE A.customer_id = 1');
  
  product := json_dyn.executeList('SELECT DISTINCT
  A.product_id,
  A.product_name,
  FROM sales A
  INNER JOIN customer B
  ON A.customer_id = B.customer_id
  WHERE A.customer_id = 1');

end;
  

Что мне нужно, так это объединить эти два select, чтобы они стали единым JSON и выглядели примерно так:
Таким образом, где product является ключом продаж, а значение product — списком продуктов

 [
  {
    "customer_id": 1,
    "customer_name": "Customer A",
    "product": [
      {
        "product_id": 5715,
        "product_name": "Product A",
      },
      {
        "product_id": 7841,
        "product_name": "Product B",
      }
    ]
  }
]
  

кто-нибудь знает, как это сделать таким образом?

Я предполагаю, что «список» получен из какой-либо таблицы:

 declare

   v_customers pljson_list := pljson_list();
   v_products  pljson_list;
   v_lists     pljson_list;
   v_customer  pljson;
   v_product   pljson;

begin

   for c in (select distinct customer_id, customer_name
               from customer
              where customer_id = 1) loop

      v_customer := pljson();
      v_customer.put('customer_id', c.customer_id);
      v_customer.put('customer_name', c.customer_name);

      v_products := pljson_list();

      for p in (select distinct product_id, product_name
                  from sales
                 where customer_id = c.customer_id) loop

         v_product := pljson();
         v_product.put('product_id', p.product_id);
         v_product.put('product_name', p.product_name);

         v_lists := json_dyn.executeList('select distinct a, b
                                            from lists
                                           where product_id = ' || p.product_id);
         v_product.put('list', v_lists.to_json_value);

         v_products.append(v_product.to_json_value);

      end loop;

      v_customer.put('products', v_products.to_json_value);

      v_customers.append(v_customer.to_json_value);

   end loop;

end;
  

HTH.

 declare

   v_customers pljson_list := pljson_list();
   v_customer  pljson;
   v_products  pljson_list;

begin

   for c in (select distinct customer_id, customer_name
               from customer
              where customer_id = 1) loop

      v_customer := pljson();
      v_customer.put('customer_id', c.customer_id);
      v_customer.put('customer_name', c.customer_name);

      v_products := json_dyn.executeList('select distinct product_id, product_name
                                            from sales
                                           where customer_id = ' || c.customer_id);
      v_customer.put('products', v_products.to_json_value);

      v_customers.append(v_customer.to_json_value);

   end loop;

end;
  

В этом фрагменте я использовал типы pljson (последнюю версию можно найти по адресуhttps://github.com/pljson/pljson ): если вы используете старую версию библиотеки, замены любого вхождения «pljson» на «json» должно быть достаточно (но я рекомендую обновить, иначе у вас могут возникнуть проблемы с Oracle 18 или новее).

@archimede таким образом, список внутри списка

 {
    "customer_id": 1,
    "customer_name": "Customer A",
    "product": [
        {
            "product_id": 5715,
            "product_name": "Product A",
            "list" : [
                {
                    "a" : 1,
                    "b": 2
                },
                {
                    "a" : 10,
                    "b" : 20
                }
            ]
        }
    ]
}