Блог

Я компилирую файл GLSL в SPIR-V с помощью команды:

 C:/VulkanSDK/1.2.148.1/Bin/glslc C:/Users/jonat/Projects/sum.comp -o C:/Users/jonat/Projects/sum.spv
  

Получение ошибки:

 error: 'subgroup op' : requires SPIR-V 1.3
  

Ошибка возникает в строках 32 и 45, которые являются обеими sum = subgroupAdd(sum);

Полный код GLSL:

 #version 450
#extension GL_KHR_shader_subgroup_arithmetic : enable

layout(std430, binding = 0) buffer Input
{
   float inputs[];
};

layout(std430, binding = 1) buffer Output
{
   float outputs[];
};

layout (local_size_x_id = 1) in;
layout (constant_id = 2) const int sumSubGroupSize = 64;

layout(push_constant) uniform PushConsts
{
  int n;
} consts;

shared float sdata[sumSubGroupSize];

void main()
{
    float sum = 0.0;
    if (gl_GlobalInvocationID.x < consts.n)
    {
        sum = inputs[gl_GlobalInvocationID.x];
    }

    sum = subgroupAdd(sum);

    if (gl_SubgroupInvocationID == 0)
    {
        sdata[gl_SubgroupID] = sum;
    }

    memoryBarrierShared();
    barrier();

    if (gl_SubgroupID == 0)
    {
        sum = gl_SubgroupInvocationID < gl_NumSubgroups ? sdata[gl_SubgroupInvocationID] : 0;
        sum = subgroupAdd(sum);
    }

    if (gl_LocalInvocationID.x == 0)
    {
        outputs[gl_WorkGroupID.x] = sum;
    }
}
  

У меня установлена последняя версия VulkanSDK.

Похоже, вам нужно --target-env=vulkan1.1 , чтобы glslc выдавал SPIR-V 1.3:

4.2.6. --target-env=

…

Сгенерированный код использует SPIR-V 1.0, за исключением кода, скомпилированного для Vulkan 1.1, который использует SPIR-V 1.3, и кода, скомпилированного для Vulkan 1.5, который использует SPIR-V 1.5.

Если эта опция не указана, используется значение по умолчанию vulkan1.0 .