Блог

Я возился с этой проблемой уже несколько часов, и, очевидно, я упускаю что-то важное. Я пытаюсь добавить несколько пустых строк в таблицу Excel на основе идентификатора критерия.

Это мой код, но каким-то образом он попадает в бесконечный цикл сразу после идентификатора 102. Я знаю, что вам нужно удалять строки снизу вверх, но не уверен, что нужно добавлять строки.

 Sub AddBlnkRow()

Dim Tbl As ListObject, TblID As Range, c As Range

Set Tbl = ActiveSheet.ListObjects("TblState")
Set TblID = Tbl.ListColumns(1).DataBodyRange


For Each c In TblID        'Step -1

   If c = 200 Or c = 300 Or c = 400 Then Tbl.ListRows.Add (c.Row - 2)

Next


End Sub
  

Приветствуется любая помощь

Ник.

Вам также следует выполнить цикл в обратном направлении, если вы добавляете строки в середине диапазона.

 Sub AddBlnkRow()
    Dim Tbl As ListObject
    Dim i As Long
    
    Set Tbl = ActiveSheet.ListObjects("TblState")
    
    With Tbl.ListColumns(1).DataBodyRange
        
        '* Count down to 2 as you don't want a blank line
        '* in the first row
        For i = .Rows.Count To 2 Step -1
            
            '* Use Mod to check if value is multiple of 100
            If .Cells(i, 1) Mod 100 = 0 And Len(.Cells(i, 1)) > 0 Then
                Tbl.ListRows.Add i
            End If
        Next i
    End With
End Sub
  

Быстрый обходной путь (добавлен skipRow для обхода ячеек, в которые ранее уже была добавлена пустая строка):

 Sub AddBlnkRow()

    Dim Tbl As ListObject, TblID As Range, c As Range
    Dim skipRow As Boolean

    Set Tbl = ActiveSheet.ListObjects("TblState")
    Set TblID = Tbl.ListColumns(1).DataBodyRange
        
    For Each c In TblID
    
            If (c = 200 Or c = 300 Or c = 400) And skipRow = False Then
                Tbl.ListRows.Add (c.Row - 2)
                skipRow = True
            Else
                skipRow = False
            End If
    
    Next

End Sub