Объединить XML-содержимое элементов с одинаковыми значениями родительских атрибутов с помощью xslt 2.0

ProgramBox

Объединить XML-содержимое элементов с одинаковыми значениями родительских атрибутов с помощью xslt 2.0

Post author:admin
Запись опубликована:16 апреля, 2023
Post category:Вопросы по программированию

#xml #xslt #xslt-2.0

Вопрос:

У меня есть два XML-файла

file1.xml

 <?xml version="1.0" encoding="UTF-8"?>
<tv>
...
  <programme start="20200814040000  0000" stop="20200814050000  0000" channel="A">
    <title>A</title>
    <sub-title>C</sub-title>
    <desc>F</desc>
  </programme>
...
  <programme start="20200814090000  0000" stop="20200814093000  0000" channel="A">
    <title>B</title>
    <sub-title>D</sub-title>
    <desc>E</desc>
  </programme>
...
</tv>

file2.xml

 <?xml version="1.0" encoding="UTF-8"?>
<tv>
...
  <programme start="20200814040000  0000" stop="20200814050000  0000" channel="A">
    <title>G</title>
    <sub-title>C</sub-title>
    <desc>H</desc>
    <episode-num system="onscreen">S9 E13</episode-num>
  </programme>
...
  <programme start="20200814090000  0000" stop="20200814093000  0000" channel="A">
    <title>K</title>
    <sub-title>L</sub-title>
    <desc>M</desc>
    <episode-num system="onscreen">S3 E2</episode-num>
  </programme>  
...
</tv>

Я хотел бы, чтобы шаблон xslt 2 получал новый файл

file3.xml

 <?xml version="1.0" encoding="UTF-8"?>
<tv>
...
  <programme start="20200814040000  0000" stop="20200814050000  0000" channel="A">
    <title>A (G)</title>
    <sub-title>C</sub-title>
    <desc>F (H)</desc>
    <episode-num system="onscreen">S9 E13</episode-num>
  </programme>
...
<programme start="20200814090000  0000" stop="20200814093000  0000" channel="A">
    <title>B (K)</title>
    <sub-title>D (L)</sub-title>
    <desc>E (M)</desc>
    <episode-num system="onscreen">S3 E2</episode-num>
  </programme>
...
</tv>

Я немного поэкспериментировал, но не смог получить ожидаемый результат. Будем признательны за любую помощь.

Отредактировано для точности

когда атрибуты программы одинаковы для каждого файла:

объединить дочерние элементы, присутствующие в обоих файлах, в один элемент в новом файле, И если текстовое содержимое узла ОТЛИЧАЕТСЯ, поместите содержимое второго файла в круглые скобки
если дочерний элемент отсутствует в обоих файлах, включите его в новый файл

1. Итак, каковы правила объединения элементов?

2. таким образом, программный элемент и его атрибуты должны быть одинаковыми, чтобы слияние произошло, и любые одинаковые дочерние элементы должны быть объединены в один элемент с содержимым второго файла в круглых скобках. Любой дочерний элемент, который отличается, включается в новый файл без каких-либо изменений

3. Релевантно ли вообще содержимое channel элемента?

4. нет, узел канала не имеет значения

Ответ №1:

В XSLT 3, возможно, функция for-each-pair может помочь:

 <?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="3.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:mf="http://example.com/mf"
  exclude-result-prefixes="#all"
  expand-text="yes">
  
  <xsl:param name="doc2">
<tv>
  <channel id="Discovery">
    <display-name lang="el">Discovery</display-name>
  </channel>
  <programme start="20200814040000  0000" stop="20200814050000  0000" channel="Discovery">
    <title lang="el">Wheeler Dealers</title>
    <sub-title lang="el">BMW Isetta</sub-title>
    <desc lang="el">Mike tracks down an Isetta Bubble. </desc>
    <episode-num system="onscreen">S9 E13</episode-num>
  </programme>
</tv>
  </xsl:param>
  
  <xsl:output indent="yes"/>
  
  <xsl:function name="mf:merge-pair">
    <xsl:param name="programme1"/>
    <xsl:param name="programme2"/>
    <xsl:if test="deep-equal($programme1/@*, $programme2/@*)">
      <xsl:copy select="$programme1">
        <xsl:apply-templates select="@*"/>
        <xsl:for-each-group select="$programme1/*, $programme2/*" composite="yes" group-by="node-name(), @*">
          <xsl:copy>
            <xsl:apply-templates select="@*"/>
            <xsl:value-of select="head(current-group()), tail(current-group()) ! ('(' || . || ')')"/>
          </xsl:copy>
        </xsl:for-each-group>
      </xsl:copy>
    </xsl:if>
  </xsl:function>

  <xsl:mode on-no-match="shallow-copy"/>

  <xsl:template match="tv">
    <xsl:copy>
      <xsl:apply-templates select="@*, channel"/>
      <xsl:sequence
         select="for-each-pair(programme, $doc2/tv/programme, mf:merge-pair#2)"/>      
    </xsl:copy>
  </xsl:template>
  
</xsl:stylesheet>

В приведенном выше примере я встроил второй документ для полноты и автономности, но, конечно, в реальном приложении вы можете использовать, например, <xsl:param name="doc2" select="doc('input2.xml')"/> .

XSLT 3 с функцией for-each-pair доступен с Saxon 10 всех выпусков или коммерческими 9.8 или 9.9 выпусками Saxon или в Saxon-JS 2 для Node.js или в браузере.

Что касается вашего комментария, похоже, вы отредактировали образцы, и теперь кажется, что дублированное содержимое, подобное BMW Isetta (BMW Isetta) , должно быть удалено, чтобы вы могли изменить

  <xsl:value-of select="head(current-group()), tail(current-group()) ! ('(' || . || ')')"/>

Для

 <xsl:value-of select="let $values := distinct-values(current-group()) return (head(
        $values), tail($values)! ('(' || . || ')'))"/>

Вывод для меня с вашими отредактированными примерами и Saxon HE 10.1 является

 <tv>
   <programme start="20200814040000  0000"
              stop="20200814050000  0000"
              channel="A">
      <title>A (G)</title>
      <sub-title>C</sub-title>
      <desc>F (H)</desc>
      <episode-num system="onscreen">S9 E13</episode-num>
   </programme>
   <programme start="20200814090000  0000"
              stop="20200814093000  0000"
              channel="A">
      <title>B (K)</title>
      <sub-title>D (L)</sub-title>
      <desc>E (M)</desc>
      <episode-num system="onscreen">S3 E2</episode-num>
   </programme>
</tv>

Полная таблица стилей — это

 <?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="3.0"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:mf="http://example.com/mf"
    exclude-result-prefixes="#all"
    expand-text="yes">
    
    <xsl:param name="doc2" select="doc('file2.xml')"/>
    
    <xsl:output indent="yes"/>
    
    <xsl:function name="mf:merge-pair">
        <xsl:param name="programme1"/>
        <xsl:param name="programme2"/>
        <xsl:if test="deep-equal($programme1/@*, $programme2/@*)">
            <xsl:copy select="$programme1">
                <xsl:apply-templates select="@*"/>
                <xsl:for-each-group select="$programme1/*, $programme2/*" composite="yes" group-by="node-name(), @*">
                    <xsl:copy>
                        <xsl:apply-templates select="@*"/>
                        <xsl:value-of select="let $values := distinct-values(current-group()) return (head(
                            $values), tail($values)! ('(' || . || ')'))"/>
                    </xsl:copy>
                </xsl:for-each-group>
            </xsl:copy>
        </xsl:if>
    </xsl:function>
    
    <xsl:mode on-no-match="shallow-copy"/>
    
    <xsl:template match="tv">
        <xsl:copy>
            <xsl:apply-templates select="@*, channel"/>
            <xsl:sequence
                select="for-each-pair(programme, $doc2/tv/programme, mf:merge-pair#2)"/>      
        </xsl:copy>
    </xsl:template>
    
</xsl:stylesheet>

1. Спасибо. Я выполнил это, но это просто дублирует содержимое каждого файла, т. Е. <title> AAAA (АААА) </title>

2. Какой инструмент вы использовали?

3. saxon 10 java в linux

4. @apt1506, я отредактировал ответ, чтобы внести изменения на основе вашего редактирования требований и образцов.

5. спасибо, это работает. Мне просто нужно было убедиться, что первый программный узел одинаков в обоих файлах;)

Ответ №2:

Я бы сделал что-то вроде:

 <xsl:variable name="file1" select="doc('file1.xml')"/>
<xsl:variable name="file2" select="doc('file2.xml')"/>

<xsl:template name="xsl:initial-template">
  <tv>
    <xsl:copy-of select="$file1/tv/channel"/>
    <xsl:for-each-group select="($file1|file2)/tv/programme"
        group-by="@stop, @start, @channel" composite="yes">
      <xsl:for-each-group select="*" group-by="node-name()">
        <xsl:element name="{name()}">
          <xsl:copy-of select="current-group()/@*"/> 
          <xsl:value-of select="current-group()[1]"/>
          <xsl:for-each select="current-group()[2]">
            <xsl:value-of select="'(', ., ')'"/>
          </xsl:for-each>
        </xsl:element>
      </xsl:for-each-group>
    </xsl:for-each-group>
  </tv>     
</xsl:template>

Не тестировалось.