xsl суммирует родственные значения

ProgramBox

xsl суммирует родственные значения

Post author:admin
Запись опубликована:22 апреля, 2023
Post category:Вопросы по программированию

#xslt

Вопрос:

у меня есть xml:

 <people>
  <man age="20" />
  <man age="40" />
  <man age="30" />
  <man age="80" />
<people>

с помощью xsl я пытаюсь вывести:

 first age:20
first and second age (combined): 60
first second and third age(combined) :110
first second third and fouth age(combined) :190

я знаю, как выбрать возраст, но как мне сложить их вместе и записать?

Также обратите внимание, что <man> элементов может быть больше, чем просто 4.

1. Является ли «первый возраст», «первый и второй возраст (комбинированный)» и т.д. Частью вашего желаемого результата? Если да, я думаю, это будет довольно сложно. Простой список сумм должен быть выполнимым (хотя у меня сейчас нет удобного решения).

2. @musiKk: мне нужны только значения, а не текст..

3. Хороший вопрос, 1. Смотрите мой ответ для получения полного, очень короткого нерекурсивного решения. 🙂

4. Также добавлено простое и эффективное решение с использованием scanl из FXSL.

Ответ №1:

Хорошо, я только что прочитал, что вам просто нужны числа, поэтому следующий разделенный xslt

 <xsl:stylesheet
        version="2.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" indent="yes" />

    <xsl:variable name="elements" select="/people/man"/>
    <xsl:variable name="count" select="count($elements)"/>

    <!-- Main Entry point -->
    <xsl:template match="/">
        <xsl:call-template name="addthem">
            <xsl:with-param name="pos" select="1"/>
            <xsl:with-param name="sum" select="$elements[1]/@age"/>
        </xsl:call-template>
    </xsl:template>

    <!-- recursive calling template to sum up the ages -->
    <xsl:template name="addthem">
        <xsl:param name="pos"/>
        <xsl:param name="sum"/>

        <xsl:value-of select="$sum"/>
        <xsl:text>
</xsl:text>

        <!-- recursive call to sum up the ages -->
        <xsl:if test="$pos lt number($count)">
            <xsl:call-template name="addthem">
                <xsl:with-param name="pos" select="$pos   1"/>
                <xsl:with-param name="sum" select="number($sum)   number($elements[$pos   1]/@age)"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

выдает следующее на вашем примере ввода-

Шаблон (оригинальный, с метками и прочим):

 <xsl:stylesheet
        version="2.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" indent="yes" />

    <xsl:variable name="txtlabels" select="tokenize('first,second,third,fourth,fifth,sixth,seventh,eights,ninth,tenth,eleventh,twelveth,thirteenth,fourteenth,fifteenth', ',')"/>

    <!-- Util template to generate labels -->
    <xsl:template name="getlabel">
        <xsl:param name="startat" select="1"/>
        <xsl:param name="idx"/>

        <xsl:if test="number($startat) lt number($idx)">
            <xsl:value-of select="$txtlabels[$startat]"/>
            <xsl:text> </xsl:text>
            <xsl:call-template name="getlabel">
                <xsl:with-param name="startat" select="$startat   1"/>
                <xsl:with-param name="idx" select="$idx"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>


    <!-- Main Entry point -->
    <xsl:template match="/">
        <xsl:variable name="count">
            <xsl:value-of select="count(/people/man)"/>
        </xsl:variable>

        <xsl:call-template name="addthem">
            <xsl:with-param name="count" select="count(/people/man)"/>
            <xsl:with-param name="pos" select="1"/>
            <xsl:with-param name="sum" select="/people/man[1]/@age"/>
            <xsl:with-param name="elements" select="/people/man"/>
        </xsl:call-template>
    </xsl:template>

    <!-- recursive calling template to sum up the ages -->
    <xsl:template name="addthem">
        <xsl:param name="count"/>
        <xsl:param name="pos"/>
        <xsl:param name="sum"/>
        <xsl:param name="elements"/>

        <!-- get the label prefix, without the 'and' clause -->
        <xsl:variable name="thelabelprefix">
            <xsl:call-template name="getlabel">
                <xsl:with-param name="startat" select="1"/>
                <xsl:with-param name="idx" select="$pos"/>
            </xsl:call-template>
        </xsl:variable>

        <!-- Now append the 'and' clause, if required, to the labels!!! -->
        <xsl:variable name="thelabel">
            <xsl:choose>
                <xsl:when test="number($pos) eq 1">
                    <xsl:value-of select="$txtlabels[$pos]"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of 
select="concat($thelabelprefix, ' and ', $txtlabels[$pos])"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:variable>

        <xsl:value-of select="$thelabel"/>
        <xsl:text> : </xsl:text> <xsl:value-of select="$sum"/>
        <xsl:text>

        </xsl:text>

        <!-- recursive call to sum up the ages -->
        <xsl:if test="$pos lt number($count)">
            <xsl:call-template name="addthem">
                <xsl:with-param name="count" select="$count"/>
                <xsl:with-param name="pos" select="$pos   1"/>
                <xsl:with-param name="sum" select="number($sum)   number($elements[$pos   1]/@age)"/>
                <xsl:with-param name="elements" select="$elements"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

создает следующий вывод для вашего входного xml:

 first : 20
first  and second : 60
first second  and third : 90
first second third  and fourth : 170

Я добавил комментарии внутри, дайте мне знать, если вам понадобится дополнительная помощь.
В основном он использует два рекурсивных шаблона, по одному для «меток», а другой для добавления.

И в вашем примере вывода должно быть указано 90 и 170 вместо 110 и 190, или в вашем примере ввода должно быть указано age = 50 вместо age = 30

Ответ №2:

Следующая краткая таблица стилей выдает именно те выходные данные, которые вы запрашивали в первую очередь, включая порядковые номера:

Таблица стилей:

 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs"
    version="2.0">

<xsl:output method="text"/>

<xsl:template match="/" >
   <xsl:for-each select="people/man">
      <xsl:for-each select=".|preceding-sibling::man">
         <xsl:value-of select="if (position() = last() and last() != 1) 
                               then ' and ' else ' '"/>
         <xsl:number format="w" ordinal="yes"/>
      </xsl:for-each>
      <xsl:text> age </xsl:text>
      <xsl:if test="position() > 1">(combined)</xsl:if>
      <xsl:value-of select="':', sum((.|preceding-sibling::man)/@age), 'amp;#xa;'"/>
  </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

Вывод:

  first age : 20 
 first and second age (combined): 60 
 first second and third age (combined): 90 
 first second third and fourth age (combined): 170

Ответ №3:

Простое, нерекурсивное решение, подходящее для инкрементных сумм небольшой последовательности родственных элементов:

 <xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="man">
  <xsl:value-of select=
    "sum(@age|preceding-sibling::man/@age)"/>
  <xsl:text>amp;#xA;</xsl:text>
 </xsl:template>
</xsl:stylesheet>

При применении к предоставленному XML-документу (исправлено для придания правильной формы):

 <people>
    <man age="20" />
    <man age="40" />
    <man age="30" />
    <man age="80" />
</people>

получен желаемый, правильный результат:

II. Простым и эффективным решением для огромных последовательностей (наборов узлов) является следующее, использующее scanl шаблон / функцию из FXSL:

 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/"
xmlns:myAdd="f:myAdd" xmlns:myParam="f:myParam"
>
  <xsl:import href="scanl.xsl"/>
  <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <myAdd:myAdd/>

  <myParam:myParam>0</myParam:myParam>

  <xsl:template match="/">

    <xsl:variable name="vFun" select="document('')/*/myAdd:*[1]"/>
    <xsl:variable name="vZero" select="document('')/*/myParam:*[1]"/>


    <xsl:call-template name="scanl">
      <xsl:with-param name="pFun" select="$vFun"/>
      <xsl:with-param name="pQ0" select="$vZero" />
      <xsl:with-param name="pList" select="/*/*/@age"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:template match="myAdd:*" mode="f:FXSL">
    <xsl:param name="pArg1" select="0"/>
    <xsl:param name="pArg2" select="0"/>

    <xsl:value-of select="$pArg1   $pArg2"/>
  </xsl:template>
</xsl:stylesheet>

Это простое решение из коробки (просто вызовите шаблон — не нужно писать рекурсивный код) выдает желаемый результат:

 <el>0</el>
<el>20</el>
<el>60</el>
<el>90</el>
<el>170</el>

1. как раз собирался вернуться и сказать, что мне удалось создать более короткую версию, и мое решение также было sum preceding-sibling . все спасибо d-live, потому что его пример заставил меня копнуть немного дальше (я проголосовал за ваш ответ)