Блог

У меня есть функция, которая получает строку тегов. Чтобы сохранить теги по отдельности, функция преобразует строку в массив:

this.tags = listToArray(this.tags, ", ");

Как мне удалить повторяющиеся значения в случае, если таковые имеются?

Мне нравится использовать Java для такого рода задач:

 <cfset tags = "apples,oranges,bananas,pears,apples" />

<cfset tagsArray = createObject("java", "java.util.ArrayList").init(
createObject("java", "java.util.HashSet").init(ListToArray(tags))
) />

<cfdump var="#tags#" />
<cfdump var="#tagsArray#" />
  

Единственная проблема в том, что он учитывает регистр, поэтому считает, что «яблоки» и «APPLES» — это разные вещи (что технически да, в зависимости от вашей системы вполне может отличаться). Обходной путь заключается в том, чтобы сначала ввести все в списке в нижний регистр. (ПРИМЕЧАНИЕ: Добавлена java.util.ArrayList функция, позволяющая идентифицировать массив и повторно использовать его с помощью Adobe ColdFusion; в противном случае такие функции, как arraysort , выдадут ошибку.)

Простой способ удалить дубликаты из списка — сначала преобразовать список в структуру, а затем преобразовать структуру в массив. Однако, если порядок элементов в списке важен, это может оказаться неподходящим, поскольку элементы в структуре будут отсортированы.

Если порядок элементов важен, вам нужно будет создать массив вручную, а не использовать функцию listToArray.

 <!--- CF9 --->
<cfset tags = "apples,oranges,bananas,pears,APPLES" />
<cfset tagArray = arrayNew(1) />

<cfloop list="#tags#" index="tag" delimiters=",">
    <cfif not ArrayFindNoCase(tagArray,tag)>
        <cfset arrayAppend(tagArray, tag) />
    </cfif>
</cfloop>
  

Поскольку вы действительно начинаете со строки / списка, который затем преобразуете в массив, вы можете передать строку через ListRemoveDuplicates перед преобразованием в массив. ListRemoveDuplicates был введен в Coldfusion 10; входные параметры (list, delimiter=»,», IgnoreCase=FALSE).

 this.tags = listToArray(listRemoveDuplicates(arrayInput,", ",TRUE));
  

Если бы вы на самом деле начинали с массива, вам нужно было бы сначала преобразовать его в список, а затем обратно.

 this.tags = listToArray(listRemoveDuplicates(arrayToList(arrayInput),", ",TRUE) );
  

основано на идее Джейсона Хариту, но вы можете сделать это в чистом CF, используя Struct! (сопоставление ключей будет нечувствительным к регистру)

 this.tags = listToArray(this.tags, ", ");
var tmpStruct = {};

for (var t in this.tags)
    tmpStruct[t] = "";

return structKeyArray(tmpStruct);
  

Однако для небольших списков я предпочитаю решение Antony.

В Coldfusion 10 или Railo 4 вы могли бы использовать функцию uniq() подчеркивания.cfc:

 _ = new Underscore();

uniqueArray = _.uniq(arrayWithDuplicates);
  

Одним из преимуществ uniq() является то, что он позволяет при необходимости передавать функцию преобразования.

Примечание: Я написал подчеркивание.cfc

Мне просто пришлось удалить очень большой список (более 5 тысяч записей) и я нашел гораздо более быстрый способ, чем использование цикла. Я чувствую необходимость поделиться.

1. преобразовать список в массив (у вас уже есть массив, поэтому пропустите) <cfset thisArray = ListToArray(thisList)>
2. Создайте запрос с помощью queryNew(«») <cfset thisQuery = QueryNew("")>
3. Добавьте столбец в этот запрос с помощью массива из шага 1 <cfset temp = QueryAddColumn(thisQuery,"items","varChar",thisArray)>
4. Запрашивать разные значения <cfquery name="qItems" dbtype="query">SELECT DISTINCT items FROM thisQuery</cfquery>
5. преобразовать результат в список <cfset returnString = ValueList(qItems.items)>
6. Вам не составит труда преобразовать этот список обратно в массив

Я записал это в функцию для удобства использования:

 <cffunction name="deDupList" output="no" returntype="string">
    <cfargument name="thisList" required="yes">
    <cfargument name="thisDelimeter" required="yes" default=",">
    <cfset var loc = StructNew()>

    <cfset loc.thisArray = ListToArray(thisList,thisDelimeter)>
    <cfset loc.thisQuery = QueryNew("")>
    <cfset loc.temp = QueryAddColumn(loc.thisQuery,"items","varChar",loc.thisArray)>
    <cfquery name="qItems" dbtype="query">
        SELECT DISTINCT items FROM loc.thisQuery
    </cfquery>
    <cfset loc.returnString = ValueList(qItems.items)>
    <cfreturn loc.returnString>
</cffunction>
  

Я сравнил его с несколькими другими методами, и вот результаты в миллисекундах:
Циклическая проверка списка на наличие > 1 экземпляра: 6265
Используя метод Генри struct: 2969
Приведенный выше метод: 31
Метод Джейсона: 30

Развивая ответ Джейсона чуть дальше, вот arrayDistinct функция.

 function arrayDistinct (required array data) {
    var output = arrayNew(1);
    output.addAll(createObject("java", "java.util.HashSet").init(arguments.data));
    return output;
}
  

Вы можете протестировать это здесь: https://trycf.com/gist/62ff904d4500519e3144fc9564d2bce7/acf

Просто поместите массив в структуру, а затем скопируйте его обратно в массив 😉

http://www.bennadel.com/blog/432-Using-ColdFusion-Structures-To-Remove-Duplicate-List-Values.htm

Я публикую еще одно удобное решение, которое мне нравится.

 arrayReduce(arrayWithDuplicates, function(resultArr, item) {
   if(!arrayFind(resultArr, item)){
      arrayAppend(resultArr, item);
   }
   return resultArr;
}, [])
  

ArrayReduce доступно с ColdFusion 11.

Но чтобы лучше ответить на вопрос, из ColdFusion 10 у нас есть ListRemoveDuplicates функция, доступная.

Итак, окончательный код может выглядеть следующим образом:

 this.tags = listToArray(listRemoveDuplicates(this.tags, ", "), ", ");
  

В CFLib есть пара UDF, которые делают это, ArrayyDiff (http://www.cflib.org/udf/arrayDiff ) и arrayCompare (http://www.cflib.org/udf/arrayCompare ).

привет, Ларри