Блог

 set PenaltyLimit = 0

:NewPass
echo Create a penalty limit 
set/p "NewPenaltyLimit=>"
--> if %NewPenaltyLimit%==Numbers?? do (
@echo %NewPenaltyLimit% >> File/PenaltyLimit.txt)
FOR /F "usebackq tokens=* delims=" %%W in ("File/PenaltyLimit.txt") do SET PenaltyLimit=%%W
goto lock

:Fail2
@set /a penalty = %penalty%   1
if %penalty%==%penaltylimit% goto DELETE
goto FAIL
  

Что бы вы поставили в обмен на строку с «—>»

Возможно ли, что вы могли бы каким-то образом либо полностью запретить кому-либо записывать что-либо, кроме чисел, либо сделать так, чтобы пакетный файл читал только числа, вместо того, чтобы ломать пакетный файл, записывая что-то случайное? (Кто-нибудь, какой пример над этим текстом)

 @echo off
setlocal

:NewPass
echo Create a password
set/p "newpass=>" || goto :NewPass
:NewPenaltyLimit
cls

echo Create a penalty limit, Numbers only
set /p "NewPenaltyLimit=>" || goto :NewPenaltyLimit
set "NewPenaltyLimit=%NewPenaltyLimit:"=%"
if not defined NewPenaltyLimit goto NewPenaltyLimit
for /f "delims=1234567890" %%A in ("%NewPenaltyLimit%") do goto NewPenaltyLimit

cls
ping localhost -n 2 > nul
echo You chose %NewPenaltyLimit% goto lock
  

Если вы разделите значение %NewPenaltyLimit% целыми числами
из 1234567890 , do goto :newPass должно произойти только
если существуют символы, отличные от целых чисел.

Из-за возможности ввода в set /p приглашение двойных кавычек, что может вызвать синтаксическую ошибку при развертывании в виде текста при разборе кода. Двойные кавычки будут заменены (удалены) из входного значения сразу после ввода. Это означает, что "86" станет 86 и будет принято как действительное число.

Пример значений:

• a1 разделитель создает токен со значением a , который вызывает goto :NewPenaltyLimit выполнение.
• 12 разделитель не создает токен, поскольку 1 и 2 оба являются разделителями.

Разрешено ли включать отложенное расширение. Эта версия может обрабатывать ввод без удаления двойных кавычек:

 @echo off
setlocal

:NewPass
echo Create a password
set/p "newpass=>" || goto :NewPass
:NewPenaltyLimit
cls

echo Create a penalty limit, Numbers only
set /p "NewPenaltyLimit=>" || goto :NewPenaltyLimit
setlocal enabledelayedexpansion
for /f "delims=1234567890" %%A in ("!NewPenaltyLimit!") do (
    endlocal
    goto NewPenaltyLimit
)
endlocal

cls
ping localhost -n 2 > nul
echo You chose %NewPenaltyLimit% goto lock
  

Отложенное расширение требуется только для for цикла,
так что это может быть лучшая версия.

!NewPenaltyLimit! не раскрывается в коде при разборе кода, что означает, что ввод, такой как "86" , не вызовет ошибки и не будет принят как число вайлда, поскольку оно заключено в двойные кавычки.

Ссылки:

• Просмотрите for /? для получения более полезной информации.

• Просмотрите set /? информацию о замене, используемой в этом ответе.

• Просмотр setlocal /? и if /? информация о задержке расширения.

Вы можете попробовать внедрить код powershell:

 <# : batch portion
@echo off amp; setlocal

    for /f "tokens=*" %%a in ('powershell -noprofile "iex (${%~f0} | out-string)"') do set "number=%%a"
    echo you've entered %number%

endlocal
goto :EOF

: end batch / begin powershell #>

do {
  [Console]::Error.Write("Enter a number:")
  $inputString = read-host
  $value = $inputString -as [Double]
  $ok = $value -ne $NULL
  if ( -not $ok ) {[Console]::Error.WriteLine("You must enter a numeric value") }
}
until ( $ok )

write-host "$value"
  

Одним из преимуществ является то, что это может поддерживать несколько типов, таких как Integer, Double, целое число без знака и так далее (в данном случае это Double .)

Вы можете попробовать также со встроенным кодом jscript (может использоваться на старых компьютерах с XP):

 @if (@X) == (@Y) @end /* JScript comment 
    @echo off 

        for /f "tokens=*" %%a in ('cscript //E:JScript //nologo "%~f0" "%~nx0" %* ') do set "number=%%a"
        echo you've entered %number%

    exit /b %errorlevel%       
@if (@X)==(@Y) @end JScript comment */


WScript.StdErr.Write("Enter a number:");
WScript.StdIn.Read(0);
var strMyName = WScript.StdIn.ReadLine();
var num=parseInt(strMyName);

while(isNaN(num)){
    WScript.StdErr.Write("Enter a number:");
    WScript.StdIn.Read(0);
    var strMyName = WScript.StdIn.ReadLine();
    var num=parseInt(strMyName);
}

WScript.StdOut.WriteLine(num);
  

Вы не можете использовать пробелы вокруг == сравнений. В вашем коде указано if %NewPenaltyLimit%<space>==<space>Numbers?? , которое никогда не будет соответствовать.