Блог

У меня есть столбец данных. У меня есть пользовательская форма с командной кнопкой на ней, которая должна создавать сводную таблицу из столбца данных.

Результатом желания является создание сводной таблицы, которая подсчитывает, сколько раз каждое число появляется в столбце данных. Однако мой код показывает только количество всех чисел (т. Е. Количество строк данных).

Может кто-нибудь, пожалуйста, помочь мне и сказать, где я ошибаюсь?

Требуемый результат представляет собой два столбца, первый из которых представляет собой метки строк, в которых перечислены все числа, а второй — количество этих чисел, показывающее, сколько раз каждое из них появляется.

 
     Dim PSheet As Worksheet
     Dim DSheet As Worksheet
     Dim LastRow As Long
     Dim LastCol As Long
     Dim PRange As Range
     Dim PCache As PivotCache
     Dim PTable As PivotTable

     Sheets.Add
     ActiveSheet.Name = "Pivottable"

    Set PSheet = Worksheets("Pivottable")
    Set DSheet = Worksheets("Sheet1")

    LastRow = DSheet.Cells(Rows.Count, 1).End(xlUp).Row
    LastCol = DSheet.Cells(1, Columns.Count).End(xlToLeft).Column
    Set PRange = DSheet.Range("A1").CurrentRegion

    Set PCache = ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=PRange)

    Set PTable = PCache.CreatePivotTable(TableDestination:=PSheet.Cells(1, 1), TableName:="PRIMEPivotTable")


   With PTable.PivotFields("Calling Number")
        .Orientation = xlColumnField
        .Position = 1

End With

With ActiveSheet.PivotTables("PRIMEPivotTable").PivotFields("Calling Number")
        .Orientation = xlRowField
        .Position = 1

    End With


    PTable.AddDataField PSheet.PivotTables _
        ("PRIMEPivotTable").PivotFields("Calling Number"), "Count of Calling Number", xlCount


End Sub```
  

Я полагаю, что вы столкнулись с некоторой придирчивостью VBA, а также с небольшой избыточностью.

Я отредактировал ваш код следующим образом:

 Sub foo()

    Dim PSheet As Worksheet
    Dim DSheet As Worksheet
    Dim LastRow As Long
    Dim LastCol As Long
    Dim PRange As Range
    Dim PCache As PivotCache
    Dim PTable As PivotTable

    Sheets.Add
    ActiveSheet.Name = "Pivottable"

    Set PSheet = Worksheets("Pivottable")
    Set DSheet = Worksheets("Sheet1")

    LastRow = DSheet.Cells(Rows.Count, 1).End(xlUp).Row
    LastCol = DSheet.Cells(1, Columns.Count).End(xlToLeft).Column
    Set PRange = DSheet.Range("A1").CurrentRegion

    Set PCache = ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=PRange)

    Set PTable = PCache.CreatePivotTable(TableDestination:=PSheet.Cells(1, 1), TableName:="PRIMEPivotTable")

    PTable.AddDataField PSheet.PivotTables( _
        "PRIMEPivotTable").PivotFields("Calling Number"), "Count of Calling Number", xlCount

    With PTable.PivotFields("Calling Number")
         .Orientation = xlRowField
         .Position = 1
    End With


End Sub
  

В вашем коде есть три операции над сводной таблицей. (1) вы добавляете «Вызывающий номер» в заголовки столбца. (2) вы добавляете «Вызывающий номер» в заголовки строк. (3) вы добавляете количество вызывающих номеров в поля данных.

Вам не нужен (1). Мы просто обрабатываем заголовки строк. Кроме того, по какой-то причине, когда вы используете то же поле в DataFields, что и в PivotFields, вам приходится добавлять поля pivot ПОСЛЕ добавления полей данных. Я действительно не знаю почему, я признаю, что наткнулся на это случайно. Но, выполнив приведенный выше фрагмент кода над некоторыми тестовыми данными, я получаю следующее (что, я думаю, вам и нужно)

Надеюсь, это поможет!