Блог

Если у меня есть файл .mxml, в котором есть метод и общедоступное свойство, могу ли я заставить метод выполняться при изменении свойства?

 <?xml version="1.0" encoding="utf-8"?>
<mx:HBox xmlns:mx="http://www.adobe.com/2006/mxml">
    <mx:Script>
        <![CDATA[           
            [Bindable]public var myProperty:MyType;

            private function myMethod(myProperty):void
            {
                // Method to run every time myProperty changes
            }
        ]]>
    </mx:Script>
</mx:HBox>
  

В другой файл .mxml я добавил этот файл .mxml следующим образом:

 <viewComponents:MyViewComponent myProperty="{myVariable}" />
  

Поскольку об этом еще никто не говорил, я предложу второй подход.

Каждое свойство в платформе Flex Framework будет отправлять свойство с именем что-то вроде *property*Changed. где property — это имя свойства, которое должно быть изменено. Указанные свойства реализованы с использованием методов get set, как упоминали другие. Что-то вроде этого:

 private var _myProperty:MyType;

[Bindable(myPropertyChanged)]
public function get myProperty():MyType
{
    return _myProperty;
}
public function set myProperty(value:MyType):void
{
    _myProperty = value;
   dispatchEvent(new Event('myPropertyChanged'));
}
  

Это имя события, указанное в привязываемых метаданных, используется для целей привязки. Итак, вместо вызова вашего метода внутри набора, вы могли бы прослушать это событие myPropertyChanged:

 component.addEventListener('myPropertyChanged',onMyPropertyChanged)
  

И в других местах кода:

 protected function onMyPropertyChanged(event:Event):void{
 // do other processing
}
  

Это может быть излишеством для того, чего вы пытаетесь достичь; или нет. Поскольку вы не вдавались в подробности того, чего вы пытались достичь, я не уверен.

Если ваша новая функциональность каким-либо образом связана с жизненным циклом компонента Flex, например, изменением отображения или размера, вам следует выполнять изменения в ethods жизненного цикла, а не в вашем методе set. Что-то вроде этого:

 private var _myProperty:MyType;
private var _myPropertyChanged:Boolean = false
[Bindable('myPropertyChanged')]
public function get myProperty():MyType
{
    return _myProperty;
}
public function set myProperty(value:MyType):void
{
    _myProperty = value;
   _myPropertyChanged = true;
   invalidateProperties();
   invalidateDisplayList();
   invalidateSize()
   invalidateSkinState(); // spark comps only
   dispatchEvent(new Event('myPropertyChanged'));
}
  

Методы invalidate принудительно перезапустят метод жизненного цикла компонента во время следующего события визуализации, и вы можете использовать подобный код в соответствующем методе:

 if(_myPropertyChanged == true){
  _myPropertyChanged = false;
  // do other processing
}
  

Вы можете использовать методы доступа get и set . Более подробная информация находится здесь.

В вашем случае это что-то вроде:

 private var _myProperty:MyType;

public function set myProperty(value:MyType):void
{
    _myProperty = value;
    // he best way is to place myMethod body here
    myMethod(_myProperty);
}

[Bindable]
public function get myProperty():MyType
{
    return _myProperty;
}
  

Вот как я бы это сделал. Создайте функцию настройки, которая вызывает предлагаемый вами метод:

 var _mystatus:Number = 0;

function set mystatus(val:Number):void
{
_mystatus = val;
alertfunction();
}

function get mystatus():Number
{
return _mystatus;
}