Блог

Во-первых, я хочу поблагодарить всех людей, которые работают на этом сайте, очень полезном для разработчика. Это первый случай, когда я заблокирован в своей разработке за последние 3 дня. Я искал решения в Интернете, но я не нахожу ничего, что решало бы эту проблему.

Итак, я разрабатываю службу, которая должна запускать внешнюю программу в vista / seven / xp при входе пользователя в систему. Некоторые характеристики этой службы :

• автоматический
• нет интерактивного.
• определить идентификатор сеанса зарегистрированного пользователя

Для запуска внешнего приложения с графическим интерфейсом в качестве интерактивного пользователя:

1. Чтобы убедиться, что сеанс пользователя открыт, я перечисляю ВСЕ «explorer.exe «обработайте, извлеките их Pid и SessionID с помощью функции msdn ProcessIdToSessionId
2. если идентификатор сеанса зарегистрированного пользователя равен идентификатору сеанса этого «explorer.exe «процесс, я уверен, что «исправный» рабочий стол запущен, так что теперь я могу выполнить внешнюю программу. (Я говорю «хороший» рабочий стол, потому что, как вы знаете, в системе может быть открыто более одного сеанса пользователя)

3. после этого я запускаю приложение с помощью этой функции:

    function RunInteractive(prog_filename: String; sessionID: Cardinal): boolean;
   var hToken: THandle;
   si: _STARTUPINFOA;
   pi: _PROCESS_INFORMATION;
   begin
   ZeroMemory(@si, SizeOf(si));
   si.cb := SizeOf(si);
   SI.lpDesktop := nil;
   if WTSQueryUserToken(sessionID, hToken)
   then  begin
         if CreateProcessAsUser(hToken, nil, PChar(prog_filename), nil, nil, False, 0, nil, PChar(ExtractFilePath(prog_filename)), si, pi)
         then  result := true
         else result := false;
       end
   else  Begin
         result := false;
         End;
   CloseHandle(hToken);
   end;
     

Этот код в порядке в большинстве случаев, за исключением одного: когда я меняю пользователя. Позвольте мне объяснить это с помощью двух простых пользователей (Domain user1 и Domain user2):

1. Чтобы быть чистым, я устанавливаю службу и перезагружаю систему
2. Я открываю сеанс с пользователем 1: внешняя программа выполнена, и я могу видеть ее форму
3. Я закрываю сеанс и открываю сессию с помощью user2: внешняя программа выполняется, и я могу видеть ее форму.

Если я делаю это X раз, результат всегда один и тот же, очень хороший … но если я делаю это:

1. Я повторно устанавливаю службу и перезагружаю систему
2. Я открываю сеанс с пользователем 1: внешняя программа выполнена, и я могу видеть ее форму
3. на этот раз я не закрываю сеанс, а меняю пользователя с помощью user2: внешняя программа выполняется, но я не могу видеть форму, и возникает ошибка: Код системной ошибки 5: Доступ запрещен.

Что-то не так, но я не нахожу решения. Спасибо за ваши ответы…

Вам не нужно перечислять запущенные explorer.exe процессы, которые вы можете использовать WTSGetActiveConsoleSessionId() вместо этого, а затем передать этот идентификатор сеанса WTSQueryUserToken() . Обратите внимание, что WTSQueryUserToken() возвращает токен олицетворения, но CreateProcessAsUser() требуется основной токен, поэтому используйте DuplicateTokenEx() для этого преобразования.

Вы также должны использовать CreateEnvironmentBlock() , чтобы созданный процесс имел надлежащую среду, подходящую для используемой учетной записи пользователя.

Наконец, установите для STARTUPINFO.lpDesktop поля значение 'WinSta0Default' вместо nil , чтобы созданный пользовательский интерфейс можно было сделать видимым правильно.

Я использую этот подход уже несколько лет, и с ним не возникало никаких проблем. Например:

 function CreateEnvironmentBlock(var lpEnvironment: Pointer; hToken: THandle; bInherit: BOOL): BOOL; stdcall; external 'userenv.dll'
function DestroyEnvironmentBlock(lpEnvironment: Pointer): BOOL; stdcall; external 'userenv.dll';

function RunInteractive(prog_filename: String): Boolean;
var
  hUserToken, hToken: THandle;
  si: _STARTUPINFOA;
  pi: _PROCESS_INFORMATION;
  SessionId: DWORD;
  Env: Pointer;
begin
  Result := False;

  ZeroMemory(@si, SizeOf(si));
  si.cb := SizeOf(si);
  si.lpDesktop := 'WinSta0Default';

  SessionId := WTSGetActiveConsoleSessionId;
  if SessionId = $FFFFFFFF then Exit;

  if not WTSQueryUserToken(SessionID, hToken) then Exit;
  try
    if not DuplicateTokenEx(hToken, MAXIMUM_ALLOWED, nil, SecurityIdentification, TokenPrimary, hUserToken) then Exit;
  finally
    CloseHandle(hToken);
  end;

  try
    if not CreateEnvironmentBlock(Env, hUserToken, False) then Exit;
    try
      Result := CreateProcessAsUser(hUserToken, nil, PChar(prog_filename), nil, nil, False, CREATE_UNICODE_ENVIRONMENT, Env, PChar(ExtractFilePath(prog_filename)), si, pi);
      if Result then
      begin
        CloseHandle(pi.hThread);
        CloseHandle(pi.hProcess);
      end;
    finally
      DestroyEnvironmentBlock(Env);
    end;
  finally
    CloseHandle(hUserToken);
  end;
end;
  

Вероятно, ваш метод получения идентификатора сеанса путем нахождения «хорошего» explorer.exe не работает для быстрого переключения пользователей.

Попробуйте зарегистрировать свое приложение для получения уведомлений об изменении сеанса с помощью WTSRegisterSessionNotification. Затем вы будете получать уведомления о переключении сеанса с указанием текущего идентификатора сеанса.

Обратите внимание на следующее:

Чтобы получать уведомления об изменении сеанса от службы, используйте функцию HandlerEx.