Блог

Я ищу способ (если это вообще возможно) использовать XSL-преобразование XSD-документа для удаления неиспользуемых элементов. Это часто встречается в моей работе, когда компания определяет XSD с абсолютно всем в нем, но затем они захотят создать урезанную версию для одного корневого элемента в нем.

Для дальнейшего объяснения у меня может быть XSD, подобный следующему:

 <?xml version="1.0" encoding="UTF-8"?>
<xs:schema xmlns:xs="http://www.w3.org/2001/XMLSchema" elementFormDefault="qualified" attributeFormDefault="unqualified">
    <xs:element name="RootElement">
        <xs:complexType>
            <xs:sequence>
                <xs:element ref="ChildElement"/>
            </xs:sequence>
        </xs:complexType>
    </xs:element>
    <xs:element name="ChildElement"/>
    <xs:element name="UnusedElement"/>
</xs:schema>
  

Что я хотел бы иметь возможность сделать, так это настроить XSL, где я предоставляю начальный элемент (в данном случае RootElement ), и он скопирует все зависимые элементы, но опустит неиспользуемые. В приведенном выше примере, если бы я передал rootElement, я ожидал бы увидеть, что RootElement и ChildElement включены, но UnusedElement опущены.

(Когда я говорю «предоставить начальный элемент», я с удовольствием открываю таблицу стилей и набираю xsl:template match="RootElement" там, где требуется.)

Очевидно, что это должно быть рекурсивным, поэтому будет осуществляться навигация по всей структуре, определенной под начальным элементом, и любой элемент в этой схеме, который не использовался, будет отброшен.

(Конечно, было бы еще лучше, если бы он мог делать то же самое в любых импортированных схемах!)

Я тщательно искал в Google и ничего не могу найти по этому поводу — я не уверен, означает ли это, что это невозможно или нет.

Спасибо!

Редактировать: На самом деле мне, вероятно, следует уточнить и сказать, что я хотел бы удалить неиспользуемые элементы И типы, чтобы они следовали по обеим ref="childElement" и type="someType" ссылкам.

Это преобразование:

 <xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema" >
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="ptopElementName" select="'RootElement'"/>

 <xsl:variable name="vTop" select=
 "/*/xs:element[@name=$ptopElementName]"/>

 <xsl:variable name="vNames"
      select="$vTop/descendant-or-self::*/@name"/>

 <xsl:variable name="vRefs"
      select="$vTop/descendant-or-self::*/@ref"/>

 <xsl:variable name="vTypes"
      select="$vTop/descendant-or-self::*/@type"/>

 <xsl:template match="node()|@*" name="identity">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="xs:element">
  <xsl:if test=
    "@name=$vNames
    or
     @name=$vRefs
    or
     ancestor-or-self::*[@name=$ptopElementName]">
   <xsl:call-template name="identity"/>
  </xsl:if>
 </xsl:template>

 <xsl:template match="xs:complexType|xs:simpleType">
  <xsl:if test=
   "@name=$vTypes
    or
     ancestor-or-self::*[@name=$ptopElementName]">
   <xsl:call-template name="identity"/>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>
  

при применении к предоставленному XML-документу:

 <xs:schema xmlns:xs="http://www.w3.org/2001/XMLSchema" elementFormDefault="qualified" attributeFormDefault="unqualified">
    <xs:element name="RootElement">
        <xs:complexType>
            <xs:sequence>
                <xs:element ref="ChildElement"/>
            </xs:sequence>
        </xs:complexType></xs:element>
    <xs:element name="ChildElement"/>
    <xs:element name="UnusedElement"/>
</xs:schema>
  

выдает желаемый, правильный результат:

 <xs:schema xmlns:xs="http://www.w3.org/2001/XMLSchema" elementFormDefault="qualified" attributeFormDefault="unqualified">
   <xs:element name="RootElement">
      <xs:complexType>
         <xs:sequence>
            <xs:element ref="ChildElement"/>
         </xs:sequence>
      </xs:complexType>
   </xs:element>
   <xs:element name="ChildElement"/>
</xs:schema>