Блог

У меня есть класс обслуживания Grails, которому необходимо выполнить некоторую очистку при завершении работы моего сервера приложений Tomcat.

Я ничего не вижу в документах Grails о методе service.stop() или destroy() или способе реализации какого-либо прослушивателя жизненного цикла приложения.

Каков наилучший способ сделать это?

Спасибо!

У вас есть пара вариантов

Внедрите свой сервис org.springframework.beans.factory.DisposableBean

 class MyService implements org.springframework.beans.factory.DisposableBean {

    void destroy() throws Exception {

    }
}
  

Или используйте аннотацию

 class MyService {

    @PreDestroy
    private void cleanUp() throws Exception {

    }
 }
  

IMO, вариант аннотации предпочтительнее, потому что вы можете присвоить своему методу деструктора более значимое имя, чем destroy , а общедоступный API ваших классов не раскрывает зависимость Spring

grails-app/conf/BootStrap.groovy может использоваться при запуске и остановке приложения.

 def init = {
  println 'Hello World!'
}

def destroy = {
  println 'Goodnight World!'
}
  

Примечание: При использовании режима разработки grails run-app в некоторых ОС CTL C JVM завершается без возможности чистого завершения работы, и закрытие destroy может не вызываться. Кроме того, если ваша JVM получит kill -9 , закрытие также не будет запущено.

Я бы попробовал внедрить службу в Bootstrap, а затем вызвать метод из блока destroy, поскольку блок destroy выполняется при завершении работы приложения, что-то вроде этого:

 class BootStrap {

    def myService

    def init = {servletContext ->
    }

    def destroy = {
       myService.cleanUp()
    }
}
  

Это не совсем то же самое, что метод удаления службы, но в итоге я зарегистрировал компонент Spring Bean с помощью метода завершения работы, который вызывается при остановке приложения.

Сначала создайте класс bean, например grails-app/utils/MyShutdownBean.groovy , который выглядит следующим образом (в имени класса или имени метода нет ничего священного, используйте все, что хотите):

 class MyShutdownBean {
    public void cleanup() {
        // Do cleanup stuff
    }
}
  

Затем зарегистрируйте компонент в grails-app/conf/spring/resources.groovy следующим образом:

 beans = {
    myShutdownHook(MyShutdownBean) { bean ->
        bean.destroyMethod='cleanup'
    }
}
  

Если вы хотите выполнять очистку только в рабочей среде, вы можете зарегистрировать ее следующим образом:

 beans = {
    if (!grails.util.GrailsUtil.isDevelopmentEnv()) {
        myShutdownHook(MyShutdownBean) { bean ->
            bean.destroyMethod='cleanup'
        }
    }
}